Setup the publishing to maven central

Author: esnaultdev

build.gradle

@@ -20,6 +20,7 @@ buildscript {
 
 plugins {
     id("org.jetbrains.dokka") version "$dokka_version"
+    id("io.github.gradle-nexus.publish-plugin") version "1.1.0"
 }
 
 allprojects {
@@ -36,3 +37,5 @@ task clean(type: Delete) {
 dokkaHtmlMultiModule.configure {
     outputDirectory = new File("${projectDir}/docs")
 }
+
+apply from: "${rootDir}/gradle/publish-root.gradle"

gradle/publish-module.gradle

@@ -0,0 +1,84 @@
+apply plugin: 'maven-publish'
+apply plugin: 'signing'
+
+task androidSourcesJar(type: Jar) {
+    archiveClassifier.set('sources')
+    if (project.plugins.findPlugin("com.android.library")) {
+        // For Android libraries
+        from android.sourceSets.main.java.srcDirs
+        from android.sourceSets.main.kotlin.srcDirs
+    } else {
+        // For pure Kotlin libraries, in case you have them
+        from sourceSets.main.java.srcDirs
+        from sourceSets.main.kotlin.srcDirs
+    }
+}
+
+task javadocJar(type: Jar, dependsOn: dokkaJavadoc) {
+    archiveClassifier.set('javadoc')
+    from dokkaJavadoc.outputDirectory
+}
+
+artifacts {
+    archives androidSourcesJar
+    archives javadocJar
+}
+
+group = PUBLISH_GROUP_ID
+version = PUBLISH_VERSION
+
+afterEvaluate {
+    publishing {
+        publications {
+            release(MavenPublication) {
+                groupId PUBLISH_GROUP_ID
+                artifactId PUBLISH_ARTIFACT_ID
+                version PUBLISH_VERSION
+
+                // Two artifacts, the `aar` (or `jar`) and the sources
+                if (project.plugins.findPlugin("com.android.library")) {
+                    from components.release
+                } else {
+                    artifact jar
+                }
+
+                artifact androidSourcesJar
+                artifact javadocJar
+
+                pom {
+                    name = PUBLISH_ARTIFACT_ID
+                    description = PUBLISH_DESCRIPTION
+                    url = rootProject.ext.githubRepoUrl
+                    licenses {
+                        license {
+                            name = "The MIT License (MIT)"
+                            url = "${rootProject.ext.githubRepoUrl}/blob/master/LICENSE"
+                            distribution = "repo"
+                        }
+                    }
+                    developers {
+                        developer {
+                            id = "esnaultdev"
+                            name = "Matthieu Esnault"
+                            email = "matthieu.esn0@gmail.com"
+                        }
+                    }
+
+                    scm {
+                        connection = "scm:git:github.com/${rootProject.ext.githubRepoName}.git"
+                        developerConnection = "scm:git:ssh://github.com/${rootProject.ext.githubRepoName}.git"
+                        url = "https://github.com/${rootProject.ext.githubRepoName}/tree/master"
+                    }
+                }
+            }
+        }
+    }
+}
+
+ext["signing.keyId"] = rootProject.ext["signing.keyId"]
+ext["signing.password"] = rootProject.ext["signing.password"]
+ext["signing.secretKeyRingFile"] = rootProject.ext["signing.secretKeyRingFile"]
+
+signing {
+    sign publishing.publications
+}

gradle/publish-root.gradle

@@ -0,0 +1,39 @@
+ext {
+    artifactVersion = '1.1.1'
+    publishGroupId = 'dev.esnault.wanakana'
+    githubRepoName = 'esnaultdev/wanakana-kt'
+    githubRepoUrl = "https://github.com/$githubRepoName"
+}
+
+// Create secret variables with empty default values
+ext["signing.keyId"] = ''
+ext["signing.password"] = ''
+ext["signing.secretKeyRingFile"] = ''
+ext["ossrhUsername"] = ''
+ext["ossrhPassword"] = ''
+ext["sonatypeStagingProfileId"] = ''
+
+File localPropsFile = project.rootProject.file('local.properties')
+if (localPropsFile.exists()) {
+    Properties properties = new Properties()
+    new FileInputStream(localPropsFile).withCloseable { is -> properties.load(is) }
+    ext["signing.keyId"] = properties.getProperty('signing.keyId', '')
+    ext["signing.password"] = properties.getProperty('signing.password', '')
+    ext["signing.secretKeyRingFile"] = properties.getProperty('signing.secretKeyRingFile', '')
+    ext["ossrhUsername"] = properties.getProperty('ossrhUsername', '')
+    ext["ossrhPassword"] = properties.getProperty('ossrhPassword', '')
+    ext["sonatypeStagingProfileId"] = properties.getProperty('sonatypeStagingProfileId', '')
+}
+
+// Set up Sonatype repository
+nexusPublishing {
+    repositories {
+        sonatype {
+            username = ossrhUsername
+            password = ossrhPassword
+            stagingProfileId = sonatypeStagingProfileId
+            nexusUrl.set(uri("https://s01.oss.sonatype.org/service/local/"))
+            snapshotRepositoryUrl.set(uri("https://s01.oss.sonatype.org/content/repositories/snapshots/"))
+        }
+    }
+}

gradle/publishing.gradle

@@ -46,4 +46,11 @@ dependencies {
     androidTestImplementation 'androidx.test.espresso:espresso-core:3.3.0'
 }
 
-apply from: "publishing.gradle"
+ext {
+    PUBLISH_GROUP_ID = rootProject.ext.publishGroupId
+    PUBLISH_VERSION = rootProject.ext.artifactVersion
+    PUBLISH_ARTIFACT_ID = 'wanakana-android'
+    PUBLISH_DESCRIPTION = 'Android bindings for WanaKana, a library for detecting and transliterating Hiragana, Katakana and Romaji.'
+}
+
+apply from: "${rootProject.projectDir}/gradle/publish-module.gradle"

wanakana-android/build.gradle

@@ -6,6 +6,8 @@ plugins {
     id("com.jfrog.bintray") version "1.8.5"
 }
 
+version = rootProject.ext.artifactVersion
+
 java {
     sourceCompatibility = JavaVersion.VERSION_1_8
     targetCompatibility = JavaVersion.VERSION_1_8
@@ -41,4 +43,11 @@ dependencies {
     testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:5.7.0"
 }
 
-apply from: "publishing.gradle"
+ext {
+    PUBLISH_GROUP_ID = rootProject.ext.publishGroupId
+    PUBLISH_VERSION = rootProject.ext.artifactVersion
+    PUBLISH_ARTIFACT_ID = 'wanakana-core'
+    PUBLISH_DESCRIPTION = 'Kotlin port of WanaKana, a library for detecting and transliterating Hiragana, Katakana and Romaji.'
+}
+
+apply from: "${rootProject.projectDir}/gradle/publish-module.gradle"