VERSION.cmake

set(VERSION_JSON_FILE "${CMAKE_CURRENT_LIST_DIR}/version.json")

if(NOT EXISTS "${VERSION_JSON_FILE}")
    message(FATAL_ERROR "version.json not found at ${VERSION_JSON_FILE}")
endif()

# Read JSON content
file(READ "${VERSION_JSON_FILE}" VERSION_JSON_CONTENT)

# Parse Version fields
string(JSON KDRIVE_VERSION_JSONOBJ GET "${VERSION_JSON_CONTENT}" "Version")
string(JSON KDRIVE_VERSION_MAJOR GET "${KDRIVE_VERSION_JSONOBJ}" "major")
string(JSON KDRIVE_VERSION_MINOR GET "${KDRIVE_VERSION_JSONOBJ}" "minor")
string(JSON KDRIVE_VERSION_PATCH GET "${KDRIVE_VERSION_JSONOBJ}" "patch")
string(JSON KDRIVE_VERSION_BUILD GET "${KDRIVE_VERSION_JSONOBJ}" "build")
string(JSON KDRIVE_VERSION_YEAR GET "${KDRIVE_VERSION_JSONOBJ}" "year")

# Composite defines
set(KDRIVE_VERSION "${KDRIVE_VERSION_MAJOR}.${KDRIVE_VERSION_MINOR}.${KDRIVE_VERSION_PATCH}")
set(KDRIVE_VERSION_FULL "${KDRIVE_VERSION}.${KDRIVE_VERSION_BUILD}")

set(KDRIVE_VERSION_STRING "${KDRIVE_VERSION}")
if(KDRIVE_VERSION_BUILD)
    set(KDRIVE_VERSION_STRING "${KDRIVE_VERSION_STRING} (build ${KDRIVE_VERSION_BUILD})")
endif()

message(STATUS "Calculated KDrive Version:")
message(STATUS "- Major: ${KDRIVE_VERSION_MAJOR}")
message(STATUS "- Minor: ${KDRIVE_VERSION_MINOR}")
message(STATUS "- Patch: ${KDRIVE_VERSION_PATCH}")
message(STATUS "- Build: ${KDRIVE_VERSION_BUILD}")
message(STATUS "- Full: ${KDRIVE_VERSION_FULL}")
message(STATUS "- Year: ${KDRIVE_VERSION_YEAR}")
message(STATUS "- Version String: ${KDRIVE_VERSION_STRING}")