mrdox cmake script for self-test.

close #41

Author: klemens-morgenstern

CMakeLists.txt

@@ -189,10 +189,26 @@ if (MRDOX_BUILD_TESTS)
     target_link_libraries(mrdox-test PRIVATE mrdox-api ${llvm_libs})
     target_include_directories(mrdox-test PRIVATE ${PROJECT_SOURCE_DIR}/source/tests)
     add_test(NAME mrdox-test COMMAND mrdox-test
-        "${PROJECT_SOURCE_DIR}/tests/old-tests"
-    )
+            "${PROJECT_SOURCE_DIR}/tests/old-tests"
+            )
     source_group(TREE ${PROJECT_SOURCE_DIR} PREFIX "" FILES CMakeLists.txt)
     source_group(TREE ${PROJECT_SOURCE_DIR}/source/tests PREFIX "source" FILES ${TEST_SOURCES})
+
+    if (CMAKE_EXPORT_COMPILE_COMMANDS)
+        # test run
+        include(mrdox.cmake)
+        set(TESTFILES
+                testfiles/decl-only/attributes_1.cpp
+                testfiles/decl-only/canonical_1.cpp
+                testfiles/decl-only/record_1.cpp
+                testfiles/decl-only/record_2.cpp)
+
+        mrdox(FORMAT adoc CONFIG mrdox.yml SOURCES ${TESTFILES})
+        mrdox(FORMAT xml  CONFIG mrdox.yml SOURCES ${TESTFILES})
+
+        add_custom_target(reference_adoc DEPENDS reference.adoc)
+        add_custom_target(reference_xml  DEPENDS reference.xml)
+    endif()
 endif()
 
 #-------------------------------------------------

mrdox.cmake

@@ -0,0 +1,64 @@
+#
+# Licensed under the Apache License v2.0 with LLVM Exceptions.
+# See https://llvm.org/LICENSE.txt for license information.
+# SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
+#
+# Copyright (c) 2023 Vinnie Falco ([email protected])
+#
+# Official repository: https://github.com/cppalliance/mrdox
+#
+
+macro(_mrdox_prep_vars)
+    if (NOT DEFINED MRDOX_EXECUTABLE)
+        set(MRDOX_EXECUTABLE $<TARGET_FILE:mrdox>)
+        set(MRDOX_EXECUTABLE_DEPENDENCY mrdox)
+    endif()
+
+    if (NOT DEFINED MRDOX_COMPILE_COMMANDS)
+        if (NOT CMAKE_EXPORT_COMPILE_COMMANDS)
+            message(FATAL_ERROR "MrDox build script requires either CMAKE_EXPORT_COMPILE_COMMANDS=ON or MRDOX_COMPILE_COMMANDS to be set")
+        else()
+            set(CMAKE_CXX_STANDARD_INCLUDE_DIRECTORIES ${CMAKE_CXX_IMPLICIT_INCLUDE_DIRECTORIES})
+        endif()
+        set(MRDOX_COMPILE_COMMANDS ${CMAKE_BINARY_DIR}/compile_commands.json)
+    endif()
+endmacro()
+
+
+function(mrdox)
+
+    cmake_parse_arguments(
+        MRDOX_TARGET
+        "" # options
+        "OUTPUT;FORMAT;CONFIG" # one_value_keywords
+        "SOURCES"
+        ${ARGN}
+    )
+
+    _mrdox_prep_vars()
+
+    if (NOT MRDOX_TARGET_CONFIG)
+        set(MRDOX_TARGET_CONFIG mrdox.yml)
+    endif()
+
+    if (NOT MRDOX_TARGET_OUTPUT)
+        set(MRDOX_TARGET_OUTPUT ${CMAKE_CURRENT_SOURCE_DIR})
+    endif()
+
+    if (NOT MRDOX_TARGET_FORMAT)
+        set(MRDOX_TARGET_FORMAT xml)
+    endif()
+
+    set(MRDOX_OUTPUT_FILE ${MRDOX_TARGET_OUTPUT}/reference.${MRDOX_TARGET_FORMAT})
+    add_custom_command(
+            OUTPUT ${MRDOX_OUTPUT_FILE}
+            COMMAND
+                mrdox --config=${CMAKE_CURRENT_SOURCE_DIR}/${MRDOX_TARGET_CONFIG}
+                        -p ${MRDOX_COMPILE_COMMANDS} ${ARGN}
+                        --format=${MRDOX_TARGET_FORMAT}
+                        --output=${MRDOX_TARGET_OUTPUT}
+            MAIN_DEPENDENCY ${MRDOX_TARGET_CONFIG} # scanner!
+            DEPENDS ${MRDOX_EXECUTABLE_DEPENDENCY} ${MRDOX_TARGET_SOURCES}
+            WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
+    )
+endfunction()

tests/mrdox.yml

@@ -0,0 +1 @@
+verbose: true