Hide all symbols by default

This prevents unmarked symbols, which we consider to be internals, from
being available on the dynamic library's dynamic symbol table (EXPORT
table on Windows).

Furthermore we split out a static library. This allows us to expose the
library internals to unit tests only, through this static library. This
works because symbol hiding only affects dynamic linking, not static
linking.

Author: muggenhor

CMakeLists.txt

@@ -1,5 +1,10 @@
 cmake_minimum_required(VERSION 3.1)
 
+if(NOT CMAKE_VERSION VERSION_LESS "3.3")
+    # Don't ignore visibility related properties for non-SHARED targets
+    cmake_policy(SET CMP0063 NEW)
+endif()
+
 project(Cucumber-Cpp)
 
 option(BUILD_SHARED_LIBS        "Generate shared libraries" OFF)

src/CMakeLists.txt

@@ -44,18 +44,28 @@ if(CMAKE_EXTRA_GENERATOR OR MSVC_IDE)
     list(APPEND CUKE_SOURCES ${CUKE_HEADERS})
 endif()
 
+# Library for unit tests relying on internals
+add_library(cucumber-cpp-internal STATIC ${CUKE_SOURCES})
+
 add_library(cucumber-cpp-nomain ${CUKE_SOURCES})
 add_library(cucumber-cpp ${CUKE_SOURCES} main.cpp)
 
-set_target_properties(cucumber-cpp cucumber-cpp-nomain PROPERTIES
-    DEFINE_SYMBOL cucumber_cpp_EXPORTS
+set_target_properties(
+    cucumber-cpp-internal
+    cucumber-cpp
+    cucumber-cpp-nomain
+    PROPERTIES
+        DEFINE_SYMBOL cucumber_cpp_EXPORTS
+        CXX_VISIBILITY_PRESET hidden
+        VISIBILITY_INLINES_HIDDEN ON
 )
 
 generate_export_header(cucumber-cpp
     EXPORT_FILE_NAME "cucumber-cpp/internal/CukeExport.hpp"
 )
 
 foreach(TARGET
+        cucumber-cpp-internal
         cucumber-cpp-nomain
         cucumber-cpp
 )
@@ -75,6 +85,11 @@ foreach(TARGET
             json_spirit.header
             ${CUKE_EXTRA_PRIVATE_LIBRARIES}
     )
+    # Don't export or import symbols for statically linked libraries
+    get_property(type TARGET ${TARGET} PROPERTY TYPE)
+    if(NOT "${type}" MATCHES "^(SHARED|MODULE)_LIBRARY$")
+        target_compile_definitions(${TARGET} PUBLIC CUCUMBER_CPP_STATIC_DEFINE)
+    endif()
     if(MINGW)
         target_link_libraries(${TARGET}
             PRIVATE

tests/CMakeLists.txt

@@ -2,7 +2,7 @@ function(cuke_add_driver_test TEST_FILE)
     get_filename_component(TEST_NAME ${TEST_FILE} NAME)
     message(STATUS "Adding " ${TEST_NAME})
     add_executable(${TEST_NAME} ${TEST_FILE}.cpp)
-    target_link_libraries(${TEST_NAME} PRIVATE cucumber-cpp-nomain ${ARGN})
+    target_link_libraries(${TEST_NAME} PRIVATE cucumber-cpp-internal ${ARGN})
     add_test(NAME ${TEST_NAME} COMMAND ${TEST_NAME})
 endfunction()
 
@@ -11,7 +11,7 @@ if(TARGET GMock::Main)
         get_filename_component(TEST_NAME ${TEST_FILE} NAME)
         message(STATUS "Adding " ${TEST_NAME})
         add_executable(${TEST_NAME} ${TEST_FILE}.cpp)
-        target_link_libraries(${TEST_NAME} PRIVATE cucumber-cpp-nomain ${ARGN} GMock::Main)
+        target_link_libraries(${TEST_NAME} PRIVATE cucumber-cpp-internal ${ARGN} GMock::Main)
         gtest_add_tests(${TEST_NAME} "" ${TEST_FILE}.cpp)
         # Run all tests in executable at once too. This ensures that the used fixtures get tested
         # properly too. Additionally gather the output in jUnit compatible output for CI.