fix: defer onTypeFormatting to after running other hooks (#4842)

If other functions on post-self-insert-hook (e.g. smart-parens,
electric-indent) run after LSP's on-type-formatting, they may modify the
buffer and therefore cancel the async reques and prevent on-type-formatting
from working as expected.

This commit updates the hook to run in a timer (after 0 seconds), so it lets
all other functions perform their changes before asking the server for a
formatting action.

Author: kassick

lsp-mode.el

@@ -5036,26 +5036,38 @@ movements may have changed the position")
   :group 'lsp-mode
   :type 'boolean)
 
+(defun lsp--on-type-formatting-do-apply (data)
+  (lsp--apply-text-edits data 'format))
 
 (defun lsp--on-type-formatting (first-trigger-characters more-trigger-characters)
   "Self insert handling.
 Applies on type formatting."
   (let ((ch last-command-event))
     (when (or (eq (string-to-char first-trigger-characters) ch)
               (cl-find ch more-trigger-characters :key #'string-to-char))
-      (lsp-request-async "textDocument/onTypeFormatting"
-                         (lsp-make-document-on-type-formatting-params
-                          :text-document (lsp--text-document-identifier)
-                          :options (lsp-make-formatting-options
-                                    :tab-size (symbol-value (lsp--get-indent-width major-mode))
-                                    :insert-spaces (lsp-json-bool (not indent-tabs-mode))
-                                    :trim-trailing-whitespace? (lsp-json-bool lsp-trim-trailing-whitespace)
-                                    :insert-final-newline? (lsp-json-bool lsp-insert-final-newline)
-                                    :trim-final-newlines? (lsp-json-bool lsp-trim-final-newlines))
-                          :ch (char-to-string ch)
-                          :position (lsp--cur-position))
-                         (lambda (data) (lsp--apply-text-edits data 'format))
-                         :mode 'tick))))
+
+      ;; defer to after hooks -- avoids the request being cancelled by smart
+      ;; parens, electric indent or other hooks
+      (run-at-time
+       0 nil
+       (lambda (pos-marker)
+         (lsp-request-async "textDocument/onTypeFormatting"
+                            (lsp-make-document-on-type-formatting-params
+                             :text-document (lsp--text-document-identifier)
+                             :options (lsp-make-formatting-options
+                                       :tab-size (symbol-value (lsp--get-indent-width major-mode))
+                                       :insert-spaces (lsp-json-bool (not indent-tabs-mode))
+                                       :trim-trailing-whitespace? (lsp-json-bool lsp-trim-trailing-whitespace)
+                                       :insert-final-newline? (lsp-json-bool lsp-insert-final-newline)
+                                       :trim-final-newlines? (lsp-json-bool lsp-trim-final-newlines))
+                             :ch (char-to-string ch)
+                             :position (lsp--point-to-position (marker-position pos-marker)))
+                            #'lsp--on-type-formatting-do-apply
+                            :mode 'tick)
+         (set-marker pos-marker nil))
+
+       ;; argument to lambda:
+       (point-marker)))))
 
 
 ;; links