FirebaseUI-Android/auth/build.gradle at e589b014458a62e376ea53a132ee91bb0b50ed65 · firebase/FirebaseUI-Android · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
apply plugin: 'com.android.library'
apply from: '../library/quality/quality.gradle'

android {
    compileSdkVersion compileSdk
    buildToolsVersion buildTools

    defaultConfig {
        minSdkVersion 16
        targetSdkVersion targetSdk
        versionCode 1
        versionName "1.0"

        vectorDrawables.useSupportLibrary = true
        resourcePrefix "fui_"
    }

    buildTypes {
        release {
            manifestPlaceholders = [enableFbLogging: true]

            minifyEnabled false
            consumerProguardFiles 'auth-proguard.pro'
        }

        debug {
            // This is needed for tests to pass. Facebook automatically enables app logging
            // which causes a null pointer exception while running tests.
            manifestPlaceholders = [enableFbLogging: false]
        }
    }

    lintOptions {
        disable 'UnusedQuantity'
    }

    testOptions {
        unitTests.all {
            testLogging {
                exceptionFormat = 'full'
            }
        }
    }
}

dependencies {
    compile "com.android.support:design:$supportLibraryVersion"
    compile "com.android.support:customtabs:$supportLibraryVersion"
    compile 'com.android.support.constraint:constraint-layout:1.1.0-beta2'

    compile "android.arch.lifecycle:extensions:$architectureVersion"
    annotationProcessor "android.arch.lifecycle:compiler:$architectureVersion"

    compile "com.google.firebase:firebase-auth:$firebaseVersion"
    compile "com.google.android.gms:play-services-auth:$firebaseVersion"

    provided 'com.facebook.android:facebook-login:4.27.0'
    provided("com.twitter.sdk.android:twitter-core:3.0.0@aar") { transitive = true }

    // The following libraries are needed to prevent incompatibilities with the facebook
    // library when updating com.android.support libraries:
    compile "com.android.support:cardview-v7:$supportLibraryVersion"

    testCompile 'junit:junit:4.12'
    //noinspection GradleDynamicVersion
    testCompile 'org.mockito:mockito-core:2.8.+'
    testCompile 'org.robolectric:robolectric:3.4'
    testCompile 'com.facebook.android:facebook-login:4.27.0'
}

javadoc.exclude([
        'com/firebase/ui/auth/provider/**',
        'com/firebase/ui/auth/ui/ExtraConstants',
        'com/firebase/ui/auth/ui/email/field_validators/**',
        'com/firebase/ui/auth/util/**',
])

javadoc.include([
        'com/google/firebase/auth/**'
])