[web] Change the structure of flutter_web_sdk.zip

Author: mdebbar

web_sdk/BUILD.gn

@@ -542,6 +542,30 @@ group("flutter_ddc_modules") {
   ]
 }
 
+if (build_canvaskit) {
+  copy("canvaskit") {
+    sources = [
+      "$root_out_dir/canvaskit/canvaskit.js",
+      "$root_out_dir/canvaskit/canvaskit.wasm",
+    ]
+    outputs = [ "$root_out_dir/flutter_web_sdk/canvaskit/{{source_file_part}}" ]
+    deps = [ "//flutter/third_party/canvaskit:canvaskit_group" ]
+  }
+}
+
+if (build_canvaskit_chromium) {
+  copy("canvaskit_chromium") {
+    sources = [
+      "$root_out_dir/canvaskit_chromium/canvaskit.js",
+      "$root_out_dir/canvaskit_chromium/canvaskit.wasm",
+    ]
+    outputs = [
+      "$root_out_dir/flutter_web_sdk/canvaskit/chromium/{{source_file_part}}",
+    ]
+    deps = [ "//flutter/third_party/canvaskit:canvaskit_chromium_group" ]
+  }
+}
+
 # Archives Flutter Web SDK
 if (!is_fuchsia) {
   zip_bundle_from_file("flutter_web_sdk_archive") {
@@ -560,13 +584,6 @@ if (!is_fuchsia) {
              ":flutter_platform_dills",
            ] + web_engine_libraries
 
-    if (build_canvaskit) {
-      deps += [ "//flutter/third_party/canvaskit:canvaskit_group" ]
-    }
-    if (build_canvaskit_chromium) {
-      deps += [ "//flutter/third_party/canvaskit:canvaskit_chromium_group" ]
-    }
-
     # flutter_ddc_modules
     sources = get_target_outputs(":flutter_dartdevc_kernel_sdk")
     sources += get_target_outputs(":flutter_dartdevc_canvaskit_kernel_sdk")
@@ -595,37 +612,21 @@ if (!is_fuchsia) {
       sources += get_target_outputs(web_engine_library)
     }
 
-    tmp_files = []
-    foreach(source, sources) {
-      tmp_files += [
-        {
-          source = rebase_path(source)
-          destination = rebase_path(source, "$root_build_dir")
-        },
-      ]
-    }
     if (build_canvaskit) {
-      tmp_files += [
-        {
-          source = rebase_path("$root_out_dir/canvaskit/canvaskit.js")
-          destination = "flutter_web_sdk/canvaskit/canvaskit.js"
-        },
-        {
-          source = rebase_path("$root_out_dir/canvaskit/canvaskit.wasm")
-          destination = "flutter_web_sdk/canvaskit/canvaskit.wasm"
-        },
-      ]
+      deps += [ ":canvaskit" ]
+      sources += get_target_outputs(":canvaskit")
     }
     if (build_canvaskit_chromium) {
+      deps += [ ":canvaskit_chromium" ]
+      sources += get_target_outputs(":canvaskit_chromium")
+    }
+
+    tmp_files = []
+    foreach(source, sources) {
       tmp_files += [
         {
-          source = rebase_path("$root_out_dir/canvaskit_chromium/canvaskit.js")
-          destination = "flutter_web_sdk/canvaskit_chromium/canvaskit.js"
-        },
-        {
-          source =
-              rebase_path("$root_out_dir/canvaskit_chromium/canvaskit.wasm")
-          destination = "flutter_web_sdk/canvaskit_chromium/canvaskit.wasm"
+          source = rebase_path(source)
+          destination = rebase_path(source, "$root_build_dir/flutter_web_sdk")
         },
       ]
     }