Automatically generate cache

Author: balsoft

changelog.md

@@ -1,6 +1,9 @@
 This file contains a summary of changes to Haskell.nix and `nix-tools`
 that will impact users.
 
+## December 10, 2019
+  * Now the `cache` attribute of `stackProject` is not required and is going to be deprecated.
+
 ## November 18, 2019
   * Changed the `cleanSourceHaskell` to accept an attrset of `src` and
     (optional) `name` parameters. This allows you to keep the source

lib/stack-cache-generator.nix

@@ -0,0 +1,35 @@
+# Generate cache entries for dependencies of package defined in `src`
+
+{ pkgs }:
+{ src, stackYaml ? "stack.yaml" }:
+let
+    s2n = import "${pkgs.fetchFromGitHub {
+       owner = "serokell";
+       repo = "stack-to-nix";
+       rev = "28e690d3eddd47c59982c7fbf4f950320ff7ff69";
+       sha256 = "1xnx5baj3k29iy8ccppn28ayf4483zddrvq6fikfpvblzp5zrnaj";
+    }}/lib.nix" pkgs;
+
+    deps = (s2n.importYAML "${src}/${stackYaml}").extra-deps or [ ];
+    hashPath = path:
+        builtins.readFile (pkgs.runCommand "hash-path" { preferLocalBuild = true; }
+            "echo -n $(${pkgs.nix}/bin/nix-hash --type sha256 --base32 ${path}) > $out");
+in with pkgs.lib;
+concatMap (dep:
+    if !builtins.isAttrs dep then
+        [ ]
+    else
+        let
+            pkgsrc = builtins.fetchGit {
+                url = dep.git;
+                ref = "*";
+                rev = dep.commit;
+            };
+        in map (subdir:
+            {
+                name = s2n.cabalPackageName "${pkgsrc}/${subdir}";
+                rev = dep.commit;
+                url = dep.git;
+                sha256 = hashPath pkgsrc;
+            } // (optionalAttrs (subdir != "") { inherit subdir; }))
+        (dep.subdirs or [ "" ])) deps

overlays/haskell.nix

@@ -300,6 +300,10 @@ self: super: {
               text = self.buildPackages.lib.concatMapStringsSep "\n" mkCacheLine repos;
           };
 
+        genStackCache = import ../lib/stack-cache-generator.nix {
+            inherit (self.buildPackages) pkgs;
+        };
+
         mkCacheModule = cache:
             # for each item in the `cache`, set
             #   packages.$name.src = fetchgit ...
@@ -315,8 +319,6 @@ self: super: {
             # src value.
             #
             # TODO: this should be moved into `call-stack-to-nix`
-            #       it should be automatic and not the burden of
-            #       the end user to work around nix peculiarities.
             { packages =
                 let
                   repoToAttr = { name, url, rev, ref ? null, sha256 ? null, subdir ? null, is-private ? false, ... }: {
@@ -334,6 +336,7 @@ self: super: {
                   cacheMap = builtins.map repoToAttr cache;
                 in
                 builtins.foldl' (x: y: x // y) {} cacheMap;
+
             };
 
         # Takes a haskell src directory runs cabal new-configure and plan-to-nix.
@@ -408,13 +411,21 @@ self: super: {
 
         stackProject' =
             { ... }@args:
-            let stack = importAndFilterProject (callStackToNix args);
+            let stack = importAndFilterProject (callStackToNix ({ inherit cache; } // args));
+                cache = if args ? cache
+                        then builtins.trace
+                            "warning: passing `cache' to `stackProject' is deprecated. See #335 #358"
+                            args.cache
+                        else genStackCache {
+                            inherit (args) src;
+                            stackYaml = args.stackYaml or "stack.yaml";
+                        };
             in let pkg-set = mkStackPkgSet
                 { stack-pkgs = stack.pkgs;
                   pkg-def-extras = (args.pkg-def-extras or []);
-                  modules = (args.modules or [])
-                          ++ self.lib.optional (args ? ghc) { ghc.package = args.ghc; }
-                          ++ self.lib.optional (args ? cache) (mkCacheModule args.cache);
+                  modules =  self.lib.singleton (mkCacheModule cache)
+                             ++ (args.modules or [])
+                             ++ self.lib.optional (args ? ghc) { ghc.package = args.ghc; };
                 };
             in { inherit (pkg-set.config) hsPkgs; stack-nix = stack.nix; };