kotlin-utils/build.gradle.kts at master · itbasis/kotlin-utils · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
import io.gitlab.arturbosch.detekt.DetektPlugin
import io.gitlab.arturbosch.detekt.extensions.DetektExtension
import org.gradle.api.publish.maven.MavenPom
import org.jetbrains.kotlin.gradle.dsl.KotlinProjectExtension
import org.jetbrains.kotlin.gradle.plugin.KotlinPlatformCommonPlugin
import org.jetbrains.kotlin.gradle.plugin.KotlinPlatformJsPlugin
import org.jetbrains.kotlin.gradle.plugin.KotlinPlatformJvmPlugin
import org.jetbrains.kotlin.gradle.plugin.KotlinPlatformPluginBase
import org.jetbrains.kotlin.gradle.tasks.KotlinCompile
import java.time.LocalDateTime
import java.time.format.DateTimeFormatter
import org.gradle.language.base.plugins.LifecycleBasePlugin.BUILD_TASK_NAME
import org.gradle.language.base.plugins.LifecycleBasePlugin.ASSEMBLE_TASK_NAME
import org.gradle.plugins.ide.idea.model.IdeaModel

buildscript {
  val kotlinVersion = extra["kotlin.version"] as String

  repositories {
    jcenter()
    gradlePluginPortal()
  }

  dependencies {
    classpath(kotlin("gradle-plugin", kotlinVersion))
    classpath("gradle.plugin.io.gitlab.arturbosch.detekt:detekt-gradle-plugin:+")
  }
}

apply {
  plugin<MavenPlugin>()
  plugin<MavenPublishPlugin>()
}

version = when (version) {
  "unspecified" -> rootDir.resolve("versions.txt").readLines().first().substringAfter("=")
  else          -> version
}

allprojects {
  group = "ru.itbasis.kotlin.utils"

  apply {
    plugin<IdeaPlugin>()
  }

  configure<IdeaModel> {
    module {
      isDownloadJavadoc = false
      isDownloadSources = false
    }
  }

  repositories {
    mavenLocal()
    jcenter()
    maven(url = "https://jitpack.io")
  }

  configurations.all {
    resolutionStrategy {
      failOnVersionConflict()

      eachDependency {
        when (requested.group) {
          "org.jetbrains.kotlin" -> useVersion(extra["kotlin.version"] as String)
          "org.junit.jupiter"    -> useVersion(extra["junit.jupiter.version"] as String)
          "org.junit.platform"   -> useVersion(extra["junit.platform.version"] as String)
        }
      }
    }
  }
}

subprojects {
  version = rootProject.version

  apply {
    plugin<BasePlugin>()
    plugin<DetektPlugin>()
    plugin<MavenPublishPlugin>()
  }

  afterEvaluate {
    plugins.withType(JavaBasePlugin::class.java) {
      configure<JavaPluginConvention> {
        sourceCompatibility = JavaVersion.VERSION_1_8
      }
    }

    tasks.withType(KotlinCompile::class.java) {
      kotlinOptions {
        jvmTarget = JavaVersion.VERSION_1_8.toString()
      }
    }
    tasks.withType(Test::class.java).all {
      failFast = true
      useJUnitPlatform {
        includeEngines("spek")
      }
      testLogging {
        showStandardStreams = true
      }
    }

    rootProject.configure<PublishingExtension> {
      publications {
        create(project.name, MavenPublication::class.java) {
          artifactId = project.name
          from(project.components["java"])
        }
      }
    }
  }

  rootProject.tasks[BUILD_TASK_NAME].shouldRunAfter(tasks[BUILD_TASK_NAME])
}

tasks.create("generateAllPomFiles") {
  group = PublishingExtension.NAME
  dependsOn(tasks.withType(GenerateMavenPom::class.java))
}
tasks.create("generateVersion").apply {
  group = LifecycleBasePlugin.BUILD_GROUP
  tasks[ASSEMBLE_TASK_NAME].shouldRunAfter(this)
  doLast {
    version = LocalDateTime.now().format(DateTimeFormatter.ofPattern("yyyyMMdd_HHmm"))
    subprojects.forEach { it.version = version }
    file("versions.txt").writeText("version=$version")
  }
}
tasks[BUILD_TASK_NAME].apply {
  doLast {
    subprojects.forEach { subProject ->
      logger.lifecycle("subProject: '${subProject.group}:${subProject.name}:${subProject.version}'")
      copy {
        from("${subProject.buildDir}/libs")
        into("$buildDir/libs")
      }
    }
  }
}