[WIP] CMake build system refactoring (#247)

* Started top level refactoring

* Top level CMake 2

* Top level CMake refactor part 3

* Top level refactoring 4

* Top level refactoring 5

* Add build status after cmake stage

* CMake modules refactoring

* Avoid python2 library detection when default python is 3

I was getting:
-- Python        | 1
--   EXE         | /usr/local/Cellar/python/3.7.2_2/bin/python
--   LIB         | /usr/lib/libpython2.7.dylib

Prefer version detected as interpreter

* Bug fix for python library detection, use pybind11 module
which has worked very well.

See: pybind/pybind11#207

* WIP Refactoring : cmake_config/CMakeLists.txt

* Refactoring of cmake_config/CMakeLists.txt part 2

* Big refactoring of src/nrniv/CMakeLists.txt

* Refactoring of src/nrnpython/CMakeLists.txt

* Bug fixes for ubuntu

Author: pramodk

CMakeLists.txt

@@ -1,81 +1,86 @@
 cmake_minimum_required(VERSION 3.3.0 FATAL_ERROR)
-project(nrn C CXX)
+project(NEURON C CXX)
 
 # =============================================================================
 # CMake common project settings
 # =============================================================================
 set(PROJECT_VERSION_MAJOR 7)
 set(PROJECT_VERSION_MINOR 7)
-set(CMAKE_BUILD_TYPE Debug)
 set(CMAKE_CXX_STANDARD 98)
 set(CMAKE_CXX_STANDARD_REQUIRED ON)
 set(CMAKE_CXX_EXTENSIONS OFF)
+set(CMAKE_BUILD_TYPE RelWithDebInfo)
 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/bin)
+set(PROJECT_VERSION ${PROJECT_VERSION_MAJOR}.${PROJECT_VERSION_MINOR})
 
-# needed in several subdirectoy configurations
-set (prefix ${CMAKE_INSTALL_PREFIX})
-set (host_cpu ${CMAKE_SYSTEM_PROCESSOR})
-set (exec_prefix ${prefix})
-set (bindir \${exec_prefix}/bin)
-set (libdir \${exec_prefix}/lib)
-set (PACKAGE "\"nrn\"")
-
-option(NRN_BUILD_SHARED "Build libraries shared or static" ON)
-option(ENABLE_INTERVIEWS "Link with INTERVIEWS GUI library" ON)
-option(ENABLE_LegacyFR "Original faraday, R, etc. instead of 2017 nist constants in share/lib/nrnunits.lib" ON)
-option(ENABLE_NRNMECH_DLL_STYLE "Dynamically load nrnmech shared library" ON)
-option(ENABLE_DISCRETE_EVENT_OBSERVER "Set to OFF if do not want Observer to be a subclass of DiscreteEvent" ON)
-option(ENABLE_PYTHON "Python interpreter available -- python3 fallback to python" ON)
-option(ENABLE_THREADS "Allow use of pthreads" ON)
-option(ENABLE_MPI "Allow use of MPI" ON)
-option(ENABLE_MEMACS "Allow use of memacs" ON)
-option(ENABLE_RX3D "Allow use of rx3d" OFF)
-
-set(INSTALL_NEURON_MODULE "YES" CACHE STRING "\"NO\", means do not \
-install the neuron module.  \"Yes\", means to install with --home in \
-CMAKE_INSTALL_PREFIX.  For installation using other modes or locations \
-use an appropriate string that goes after python setup.py install")
-
-set(NRNPYTHON_DYNAMIC "NO" CACHE STRING "\"NO\", means the nrnpython
-interface is linked into libnrniv.so.  \"YES\" means the nrnpython
-interface consistent with default python3 (falling back to python) is
-built and loaded dynamically at run time (nrniv still works in the
-absence of any Python at all).  A ';' separated list of executable
-pythons are used to create a separate interface for each.  When one of
-those versions of Python is lauched,
-  import neuron
-will automatically load the appropriate module interface along with the
-rest of neuron.  (And
-  nrniv -pyexe <python>
-will work with any <python> in the list of python executables.")
+# =============================================================================
+# Build options (boolean)
+# =============================================================================
+option(NRN_BUILD_SHARED "Build shared libraries (otherwise static library)" ON)
+option(NRN_ENABLE_INTERVIEWS "Enable GUI with INTERVIEWS" ON)
+option(NRN_ENABLE_LEGACY_FR "Use original faraday, R, etc. instead of 2017 nist constants" ON)
+option(NRN_ENABLE_MECH_DLL_STYLE "Dynamically load nrnmech shared library" ON)
+option(NRN_ENABLE_DISCRETE_EVENT_OBSERVER "Enable Observer to be a subclass of DiscreteEvent" ON)
+option(NRN_ENABLE_PYTHON "Enable Python interpreter support (default python3 fallback to python)" ON)
+option(NRN_ENABLE_THREADS "Allow use of Pthreads" ON)
+option(NRN_ENABLE_MPI "Enable MPI support" ON)
+option(NRN_ENABLE_MEMACS "Enable use of memacs" ON)
+option(NRN_ENABLE_RX3D "Enable rx3d support" OFF)
 
-set(NRNMPI_DYNAMIC "NO" CACHE STRING "\"No\", means the nrnmpi
-is linked into libnrniv.so.  \"YES\", means the nrnmpi interface
-consistent with default mpi is built and loaded dynamically at run
-time (nrniv still works in the absence of any mpi at all). A ';'
-separated list of paths to mpi package bin directories is used to
-create a separate libnrnmpi_xxx.so interface for each. When nrniv
-is launched with the -mpi argument, the first mpi found will determine
-which interface is dynamically loaded.")
+# =============================================================================
+# Build options (string)
+# =============================================================================
 
-set(USING_CMAKE_FALSE "#")
-set(USING_CMAKE_TRUE "")
+# NEURON module installation:
+#   - NO        : do not install
+#   - YES       : install with --home in ${CMAKE_INSTALL_PREFIX}
+#   - <string>  : install using other modes or locations using an appropriate
+#                 string that goes after python setup.py install
+# Dynamic Python version support:
+#   - NO        : nrnpython interface is linked into libnrniv.so
+#   - YES       : nrnpython interface consistent with default python3 (falling back to python)
+#                 is built and loaded dynamically at run time (nrniv still works in the absence
+#                 of any Python at all).
+#   - <string>  : semicolon (;) separated list of python executable used to create a separate
+#                 interface for each. When one of those versions of Python is lauched,
+#                 "import neuron" will automatically load the appropriate module interface along
+#                 with the rest of neuron. Alsom nrniv -pyexe <python> will work with any <python>
+#                 in the list of python executables.
+# Dynamic MPI support:
+#   - NO        : nrnmpi is linked into libnrniv.so
+#   - YES       : nrnmpi interface is consistent with default mpi is built and loaded dynamically
+#                 at run time (nrniv still works in the absence of any mpi at all).
+#   - <string>  : semicolon (;) separated list of MPI's bin directories to create a separate
+#                 libnrnmpi_xxx.so interface for each. When nrniv is launched with the -mpi argument,
+#                 the first mpi found will determine which interface is dynamically loaded."
+set(NRN_ENABLE_MODULE_INSTALL YES CACHE STRING "Enable NEURON module installation (with setup.py)")
+set(NRN_ENABLE_PYTHON_DYNAMIC "NO" CACHE STRING "Enable dynamic Python version support")
+set(NRN_ENABLE_MPI_DYNAMIC "NO" CACHE STRING "Enable dynamic MPI library support")
 
 # =============================================================================
-# Compile static libraries with hidden visibility
+# Include cmake modules
 # =============================================================================
-#set(CMAKE_CXX_VISIBILITY_PRESET hidden)
+list(APPEND CMAKE_MODULE_PATH
+            ${PROJECT_SOURCE_DIR}/cmake
+            ${PROJECT_SOURCE_DIR}/cmake/modules)
+include(CompilerHelper)
+include(MacroHelper)
+include(RpathHelper)
+include(PlatformHelper)
 
 # =============================================================================
 # Find required packages
 # =============================================================================
-message(STATUS "CHECKING FOR X11")
 find_package(BISON)
 find_package(FLEX)
+find_package(readline)
 
-if (ENABLE_MPI)
+# =============================================================================
+# Enable MPI/Python/IV/Pthead if found
+# =============================================================================
+# enable mpi if found
+if (NRN_ENABLE_MPI)
   find_package(MPI REQUIRED)
-  # TODO : include this for only selective target
   include_directories(${MPI_INCLUDE_PATH})
   set(NRNMPI 1)
   set(PARANEURON 1)
@@ -84,36 +89,34 @@ else()
   set(PARANEURON 0)
 endif()
 
-if (ENABLE_INTERVIEWS)
+# enable interviews if found
+if (NRN_ENABLE_INTERVIEWS)
   find_package(X11)
   if(NOT ${X11_FOUND})
     if (APPLE)
       message(FATAL_ERROR "You must install XQuartz from https://www.xquartz.org/ to build iv")
     else()
-      find_package(X11 REQUIRED)
+      message(FATAL_ERROR "You must install X11 to build iv e.g. 'apt install libx11-dev libxcomposite-dev' on Ubuntu")
     endif()
   endif()
-  include_directories(${X11_INCLUDE_DIR})
   find_package(iv REQUIRED)
+  include_directories(${X11_INCLUDE_DIR})
   set (HAVE_IV 1)
 else()
-  set (HAVE_IV 0)
+  set(HAVE_IV 0)
 endif()
 
-# python or python3 is also needed to make hocusr.h from neuron.h
-set(Python_ADDITIONAL_VERSIONS 3.6) # 3.x priority, then 2.x
-find_package(PythonInterp REQUIRED) #currently active
-message(NOTICE "ENABLE_PYTHON ${ENABLE_PYTHON}")
-if (ENABLE_PYTHON)
-  message(NOTICE " inside ENABLE_PYTHON")
-  find_package(PythonLibs REQUIRED) # consistent with above
+# enable python support (interpreter needed to make hocusr.h from neuron.h, prefer Python 3)
+find_package(PythonInterp REQUIRED)
+if (NRN_ENABLE_PYTHON)
+  find_package(PythonLibsNew ${PYTHON_VERSION_MAJOR} REQUIRED)
   set(USE_PYTHON 1)
-  message(NOTICE "USE_PYTHON ${USE_PYTHON}")
 else()
   set(USE_PYTHON 0)
 endif()
 
-if (ENABLE_THREADS)
+# enable threads if found
+if (NRN_ENABLE_THREADS)
   set(THREADS_PREFER_PTHREAD_FLAG ON)
   find_package(Threads REQUIRED)
   set(USE_PTHREAD 1)
@@ -122,70 +125,89 @@ else()
 endif()
 
 # =============================================================================
-# Include cmake modules
+# Add CMake modules AFTER setting options
 # =============================================================================
-list(APPEND CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
-include(RpathHelper)
-include(ConfigACFile)
-include(NrnPyDynamic)
-include(NrnMPIDynamic)
+include(ConfigFileSetting)
+include(NeuronFileLists)
+include(PythonDynamicHelper)
+include(MPIDynamicHelper)
 
 # =============================================================================
 # Project version from git and project directories
 # =============================================================================
-set(PROJECT_VERSION ${PROJECT_VERSION_MAJOR}.${PROJECT_VERSION_MINOR})
-
-add_definitions(-DHAVE_CONFIG_H)
-
-if(${CMAKE_SYSTEM_NAME} MATCHES "CYGWIN")
-  set(CYGWIN 1)
+add_subdirectory(cmake_config)
+add_subdirectory(src/nrniv)
+add_subdirectory(bin)
+if (NRN_ENABLE_PYTHON)
+  add_subdirectory(src/nrnpython)
+endif()
+if (NRN_MACOS_BUILD OR NOT ${READLINE_FOUND})
+    add_subdirectory(src/readline)
+    set(INTERNAL_READLINE readline)
+    unset(Readline_LIBRARY CACHE)
 endif()
 
-add_subdirectory(cmkconfig)
+# =============================================================================
+# Install targets
+# =============================================================================
+# find headers to install
+nrn_find_project_files(NRN_HEADERS_PATHS ${HEADER_FILES_TO_INSTALL})
 
-install(DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/share/lib
-  DESTINATION share/nrn)
-install(DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/share/demo
-  DESTINATION share/nrn)
-install(FILES ${PROJECT_BINARY_DIR}/share/lib/nrnunits.lib
+install(DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/share/lib DESTINATION share/nrn)
+install(DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/share/demo DESTINATION share/nrn)
+install(FILES
+  ${PROJECT_BINARY_DIR}/share/lib/nrnunits.lib
   ${PROJECT_BINARY_DIR}/share/lib/nrn.defaults
   DESTINATION ${CMAKE_INSTALL_PREFIX}/share/nrn/lib
 )
-install(PROGRAMS ${CMAKE_CURRENT_SOURCE_DIR}/share/lib/cleanup
+install(PROGRAMS
+  ${CMAKE_CURRENT_SOURCE_DIR}/share/lib/cleanup
   DESTINATION ${CMAKE_INSTALL_PREFIX}/share/nrn/lib
 )
-
-# paths to *.h files for installing into <prefix>/include
-my_find_files(inst_inc
-  cabvars.h    hoc_membf.h   neuron.h      nrnjava.h     options.h
-  cspmatrix.h  hocparse.h    nmodlmutex.h  nrnoc_ml.h    scoplib_ansi.h
-  cspredef.h   md1redef.h    nrn_ansi.h    scoplib.h
-  hocassrt.h   md2redef.h    nrnapi.h      nrnran123.h   section.h
-  hocdec.h     membdef.h     nrnassrt.h    nrnredef.h    spconfig.h
-  hocgetsym.h  membfunc.h    nrncvode.h    oc_ansi.h     spmatrix.h
-  hoc.h        multicore.h   nrnisaac.h    ocfunc.h
-  hoclist.h    multisplit.h  nrniv_mf.h    ocmisc.h
-)
-install(FILES ${inst_inc} ${PROJECT_BINARY_DIR}/src/oc/nrnpthread.h
+install(FILES
+  ${NRN_HEADERS_PATHS} ${PROJECT_BINARY_DIR}/src/oc/nrnpthread.h
   DESTINATION ${CMAKE_INSTALL_PREFIX}/include
 )
 
-find_package(readline)
-
-# if readline not found or if we are on OSX, use internal readline
-# also clear library variable
-if (${CMAKE_SYSTEM_NAME} MATCHES "Darwin" OR NOT ${READLINE_FOUND})
-    add_subdirectory(src/readline)
-    set(INTERNAL_READLINE readline)
-    unset(Readline_LIBRARY CACHE)
-endif()
-
-if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
-  set(CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS "${CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS} -undefined dynamic_lookup")
-endif()
-
-add_subdirectory(src/nrniv)
-add_subdirectory(bin)
-if (ENABLE_PYTHON)
-  add_subdirectory(src/nrnpython)
+# =============================================================================
+# Print build status
+# =============================================================================
+message(STATUS "")
+message(STATUS "Configured NEURON ${PROJECT_VERSION}")
+message(STATUS "")
+string(TOLOWER "${CMAKE_GENERATOR}" cmake_generator_tolower)
+if(cmake_generator_tolower MATCHES "makefile")
+  message(STATUS "Some things you can do now:")
+  message(STATUS "--------------+--------------------------------------------------------------")
+  message(STATUS "Command       |   Description")
+  message(STATUS "--------------+--------------------------------------------------------------")
+  message(STATUS "make install  | Will install NEURON to: ${CMAKE_INSTALL_PREFIX}")
+  message(STATUS "              | Change the install location of NEURON using:")
+  message(STATUS "              |     cmake <src_path> -DCMAKE_INSTALL_PREFIX=<install_path>")
+  message(STATUS "make doc      | Build the API documentation, requires Sphinx")
+  message(STATUS "make uninstall| Removes files installed by make install")
+  message(STATUS "--------------+--------------------------------------------------------------")
+  message(STATUS " Build option | Status")
+  message(STATUS "--------------+--------------------------------------------------------------")
+  message(STATUS "Interviews    | ${HAVE_IV}")
+  message(STATUS "MPI           | ${NRNMPI}")
+  if(NRN_ENABLE_MPI)
+  message(STATUS "  INC         | ${MPI_INCLUDE_PATH}")
+  message(STATUS "  LIB         | ${MPI_LIBRARY}")
+  endif()
+  message(STATUS "Python        | ${USE_PYTHON}")
+  if(NRN_ENABLE_PYTHON)
+  message(STATUS "  EXE         | ${PYTHON_EXECUTABLE}")
+  message(STATUS "  LIB         | ${PYTHON_LIBRARY}")
+  if (NOT NRN_ENABLE_PYTHON_DYNAMIC MATCHES "NO")
+  message(STATUS "  INC(2)      | ${NRNPYTHON_INCLUDE2}")
+  message(STATUS "  INC(3)      | ${NRNPYTHON_INCLUDE3}")
+  endif()
+  endif()
+  message(STATUS "RXD           | ${NRN_ENABLE_RX3D}")
+  message(STATUS "Shared        | ${NRN_BUILD_SHARED}")
+  message(STATUS "--------------+--------------------------------------------------------------")
+  message(STATUS " See documentation : https://www.neuron.yale.edu/neuron/")
+  message(STATUS "--------------+--------------------------------------------------------------")
 endif()
+message(STATUS "")

bin/CMakeLists.txt

@@ -28,11 +28,11 @@ include(${CMAKE_CURRENT_SOURCE_DIR}/CMakeListsNrnMech.txt)
 
 set(NRNMECH_DLL_STYLE_FALSE "\#")
 set(NRNMECH_DLL_STYLE_TRUE "")
-configure_ac_file(nrngui bin)
-configure_ac_file(neurondemo bin)
-configure_ac_file(nrnivmodl bin)
+nrn_configure_file(nrngui bin)
+nrn_configure_file(neurondemo bin)
+nrn_configure_file(nrnivmodl bin)
 #nrnmech_makefile.in is intimately bound up with autoconf (libtool)
-#configure_ac_file(nrnmech_makefile bin)
+#nrn_configure_file(nrnmech_makefile bin)
 #so instead use a modified copy of the CoreNEURON version of
 #nrnivmodl_core_makefile.in
 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/nrnivmodl_makefile.cmk

bin/CMakeListsNrnMech.txt

@@ -43,7 +43,7 @@ endif()
 string(TOUPPER "${CMAKE_BUILD_TYPE}" _BUILD_TYPE)
 set(BUILD_TYPE_C_FLAGS "${CMAKE_C_FLAGS_${_BUILD_TYPE}}")
 set(BUILD_TYPE_CXX_FLAGS "${CMAKE_CXX_FLAGS_${_BUILD_TYPE}}")
-message("CXX Compile Flags from BUILD_TYPE: ${BUILD_TYPE_CXX_FLAGS}")
+message(STATUS "CXX Compile Flags from BUILD_TYPE: ${BUILD_TYPE_CXX_FLAGS}")
 
 if (FALSE) # done in top level CMakeLists.txt
 configure_file(${nmodl_makefile}.in ${nmodl_makefile} @ONLY)

bin/nrndiagnose.sh.in

@@ -23,7 +23,7 @@ PYTHONBLD="@PYTHON_BLD@" # The python used for
 PYTHONCFG="@PYTHON@" # The Python from --with_nrnpython or --pyexe
 host_cpu="@host_cpu@"
 host_os="@host_os@"
-NRNPYTHON_DYNAMIC=no
+NRN_ENABLE_PYTHON_DYNAMIC=no
 nrnPYTHONPATH="$prefix/lib/python"
 
 diagnose() {
@@ -40,7 +40,7 @@ diagnose() {
   echo "PYTHON=$PYTHON"
   echo "host_cpu=$host_cpu"
   echo "host_os=$host_os"
-  echo "NRNPYTHON_DYNAMIC=$NRNPYTHON_DYNAMIC"
+  echo "NRN_ENABLE_PYTHON_DYNAMIC=$NRN_ENABLE_PYTHON_DYNAMIC"
   echo "origPYTHONPATH=$origPYTHONPATH"
   echo "origPYTHONHOME=$origPYTHONHOME"
   echo "origNRN_PYLIB=$origNRN_PYLIB"
@@ -95,7 +95,7 @@ unset PYTHONPATH # pristine, just going to check for runability
 
 PYTHON=""
 if test "@BUILD_NRNPYTHON_DYNAMIC_FALSE@" = "#" ; then
-  NRNPYTHON_DYNAMIC=yes
+  NRN_ENABLE_PYTHON_DYNAMIC=yes
   if $PYTHONCFG -c 'quit()' > /dev/null 2>& 1 ; then
     PYTHON="$PYTHONCFG" #last one built
   else # python for last one built is not on this machine

cmake/CompilerHelper.cmake

@@ -0,0 +1,6 @@
+# =============================================================================
+# Compiler specific settings
+# =============================================================================
+if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
+  set(CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS "${CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS} -undefined dynamic_lookup")
+endif()