WIP homestead command

Author: noahfrederick

autoload/laravel.vim

@@ -134,8 +134,14 @@ function! s:app_views_path(...) dict abort
   return join([self._root, 'resources/views'] + a:000, '/')
 endfunction
 
+""
+" Get path to source root in Homestead VM.
+function! s:app_homestead_root() dict abort
+  return laravel#homestead#root(self._root)
+endfunction
+
 call s:add_methods('app', ['glob', 'has_dir', 'has_file', 'has_path'])
-call s:add_methods('app', ['path', 'src_path', 'config_path', 'migrations_path', 'find_migration', 'expand_migration', 'views_path'])
+call s:add_methods('app', ['path', 'src_path', 'config_path', 'migrations_path', 'find_migration', 'expand_migration', 'views_path', 'homestead_root'])
 
 ""
 " Detect app's namespace
@@ -468,6 +474,21 @@ function! laravel#buffer_commands() abort
   " Invoke Artisan with [arguments] (with intelligent completion).
   command! -buffer -bang -bar -nargs=* -complete=customlist,laravel#artisan#complete
         \ Artisan execute laravel#artisan#exec(<q-bang>, <f-args>)
+
+  ""
+  " @command Homestead {cmd}
+  " Invoke shell {cmd} on the Homestead VM over SSH.
+  "
+  " @command Homestead
+  " Start an interactive SSH session on the Homestead VM.
+  "
+  " @command Homestead! [arguments]
+  " Invoke Vagrant with [arguments] in the context of the Homestead directory
+  " on the host machine. For example, to start the VM: >
+  "     :Homestead! up
+  " <
+  command! -buffer -bang -bar -nargs=* -complete=shellcmd
+        \ Homestead execute laravel#homestead#exec(<q-bang>, <f-args>)
 endfunction
 
 ""

autoload/laravel/homestead.vim

@@ -0,0 +1,93 @@
+" autoload/laravel/homestead.vim - Laravel Homestead support for Vim
+" Maintainer: Noah Frederick
+
+""
+" @setting g:laravel_homestead_dir
+" The directory where Homestead is installed.
+let s:dir = get(g:, 'laravel_homestead_dir', '~/Homestead')
+let s:json = s:dir . '/Homestead.json'
+
+""
+" Change working directory to {dir}, respecting current window's local dir
+" state. Returns old working directory to be restored later by a second
+" invocation of the function.
+function! s:cd(dir) abort
+  let cd = exists('*haslocaldir') && haslocaldir() ? 'lcd' : 'cd'
+  let cwd = getcwd()
+  execute cd fnameescape(a:dir)
+  return cwd
+endfunction
+
+""
+" Escape arguments to be passed to ssh.
+function! s:prepare_args(args) abort
+  return shellescape(join(a:args))
+endfunction
+
+""
+" Build SSH shell command from command-line arguments.
+function! s:ssh(args) abort
+  let root = laravel#app().homestead_root()
+
+  if empty(root)
+    echoerr 'Homestead site not configured for ' . laravel#app().path()
+  endif
+
+  if empty(a:args)
+    return 'vagrant ssh'
+  endif
+
+  let args = insert(a:args, 'cd ' . root . ' &&')
+  return 'vagrant ssh -- ' . s:prepare_args(args)
+endfunction
+
+""
+" Build Vagrant shell command from command-line arguments.
+function! s:vagrant(args) abort
+  if empty(a:args)
+    return 'vagrant status'
+  endif
+
+  return 'vagrant ' . join(a:args)
+endfunction
+
+""
+" The :Homestead command.
+function! laravel#homestead#exec(...) abort
+  let args = copy(a:000)
+  let vagrant = remove(args, 0)
+
+  if !isdirectory(s:dir)
+    echoerr 'Homestead directory does not exist: ' . s:dir
+          \ . ' (set g:laravel_homestead_dir)'
+  endif
+
+  let cmdline = vagrant ==# '!' ? s:vagrant(args) : s:ssh(args)
+
+  if exists(':terminal')
+    tabedit %
+    execute 'lcd' fnameescape(s:dir)
+    execute 'terminal' cmdline
+  else
+    let cwd = s:cd(s:dir)
+    execute '!' . cmdline
+    call s:cd(cwd)
+  endif
+
+  return ''
+endfunction
+
+function! laravel#homestead#root(app_root) abort
+  " TODO: Read homestead.json configuration file instead:
+  return get(get(g:, 'laravel_homestead_sites', {}), a:app_root, '')
+endfunction
+
+""
+" @private
+" Hack for testing script-local functions.
+function! laravel#homestead#sid()
+  nnoremap <SID> <SID>
+  return maparg('<SID>', 'n')
+endfunction
+
+" vim: fdm=marker:sw=2:sts=2:et

doc/laravel.txt

@@ -15,6 +15,7 @@ Some features include:
 
   * The |:Artisan| command wraps artisan with intelligent completion.
   * Includes projections for projectionist.vim.
+  * Use |:Homestead| to send commands over SSH to your development VM.
   * Use |:Console| to fire up a REPL (artisan tinker).
 
 This plug-in is only available if 'compatible' is not set.
@@ -25,6 +26,21 @@ COMMANDS                                                    *laravel-commands*
 :Artisan[!] [arguments]                                             *:Artisan*
   Invoke Artisan with [arguments] (with intelligent completion).
 
+:Homestead {cmd}                                                  *:Homestead*
+  Invoke shell {cmd} on the Homestead VM over SSH.
+
+
+:Homestead
+  Start an interactive SSH session on the Homestead VM.
+
+
+:Homestead! [arguments]
+  Invoke Vagrant with [arguments] in the context of the Homestead directory on
+  the host machine. For example, to start the VM:
+>
+      :Homestead! up
+<
+
 ==============================================================================
 ABOUT                                                          *laravel-about*
 

plugin/laravel.vim

@@ -9,6 +9,7 @@
 "
 " * The |:Artisan| command wraps artisan with intelligent completion.
 " * Includes projections for projectionist.vim.
+" * Use |:Homestead| to send commands over SSH to your development VM.
 " * Use |:Console| to fire up a REPL (artisan tinker).
 "
 " This plug-in is only available if 'compatible' is not set.