Squashme: result of George+Jeff discussion. This may actually fix the

IBM CI (and I may have unfairly been maligning IBM's CI if it was
showing an actual problem... oops!).

Signed-off-by: Jeff Squyres <[email protected]>

Author: jsquyres

config/opal_config_asm.m4

@@ -131,6 +131,9 @@ dnl Check with:
 dnl 1. No compiler/linker flags.
 dnl 2. CFLAGS += -mcx16
 dnl 3. LIBS += -latomic
+dnl 4. Finally, if it links ok with any of #1, #2, or #3, actually try
+dnl to run the test code (if we're not cross-compiling) and verify
+dnl that it actually gives us the correct result.
 dnl
 dnl Note that we unfortunately can't use AC SEARCH_LIBS because its
 dnl check incorrectly fails (because these functions are special compiler
@@ -150,7 +153,10 @@ dnl $3: action if any of 1, 2, or 3 succeeds
 dnl #4: action if all of 1, 2, and 3 fail
 dnl
 AC_DEFUN([OPAL_ASM_CHECK_ATOMIC_FUNC],[
-    OPAL_VAR_SCOPE_PUSH([opal_asm_check_func_happy opal_asm_check_func_FLAGS_save])
+    OPAL_VAR_SCOPE_PUSH([opal_asm_check_func_happy opal_asm_check_func_CFLAGS_save opal_asm_check_func_LIBS_save])
+
+    opal_asm_check_func_CFLAGS_save=$CFLAGS
+    opal_asm_check_func_LIBS_save=$LIBS
 
     dnl Check with no compiler/linker flags
     AC_MSG_CHECKING([for $1])
@@ -163,29 +169,45 @@ AC_DEFUN([OPAL_ASM_CHECK_ATOMIC_FUNC],[
     dnl If that didn't work, try again with CFLAGS+=mcx16
     AS_IF([test $opal_asm_check_func_happy -eq 0],
         [AC_MSG_CHECKING([for $1 with -mcx16])
-         opal_asm_check_func_FLAGS_save=$CFLAGS
          CFLAGS="$CFLAGS -mcx16"
          AC_LINK_IFELSE([$2],
              [opal_asm_check_func_happy=1
               AC_MSG_RESULT([yes])],
              [opal_asm_check_func_happy=0
-              CFLAGS=$opal_asm_check_func_FLAGS_save
+              CFLAGS=$opal_asm_check_func_CFLAGS_save
               AC_MSG_RESULT([no])])
          ])
 
     dnl If that didn't work, try again with LIBS+=-latomic
     AS_IF([test $opal_asm_check_func_happy -eq 0],
         [AC_MSG_CHECKING([for $1 with -latomic])
-         opal_asm_check_func_FLAGS_save=$LIBS
          LIBS="$LIBS -latomic"
          AC_LINK_IFELSE([$2],
              [opal_asm_check_func_happy=1
               AC_MSG_RESULT([yes])],
              [opal_asm_check_func_happy=0
-              LIBS=$opal_asm_check_func_FLAGS_save
+              LIBS=$opal_asm_check_func_LIBS_save
               AC_MSG_RESULT([no])])
          ])
 
+    dnl If we have it, try it and make sure it gives a correct result.
+    dnl As of Aug 2018, we know that it links but does *not* work on clang
+    dnl 6 on ARM64.
+    AS_IF([test $opal_asm_check_func_happy -eq 1],
+        [AC_MSG_CHECKING([if $1 gives correct results])
+         AC_RUN_IFELSE([$2],
+              [AC_MSG_RESULT([yes])],
+              [opal_asm_check_func_happy=0
+               AC_MSG_RESULT([no])],
+              [AC_MSG_RESULT([cannot test -- assume yes (cross compiling)])])
+         ])
+
+    dnl If we were unsuccessful, restore CFLAGS/LIBS
+    AS_IF([test $opal_asm_check_func_happy -eq 0],
+        [CFLAGS=$opal_asm_check_func_CFLAGS_save
+         LIBS=$opal_asm_check_func_LIBS_save])
+
+    dnl Run the user actions
     AS_IF([test $opal_asm_check_func_happy -eq 1], [$3], [$4])
 
     OPAL_VAR_SCOPE_POP
@@ -204,17 +226,6 @@ AC_DEFUN([OPAL_CHECK_SYNC_BUILTIN_CSWAP_INT128], [
       [sync_bool_compare_and_swap_128_result=1],
       [sync_bool_compare_and_swap_128_result=0])
 
-  # If we have it, try it, and make sure it works.  As of Aug 2018, we
-  # know that it links but does *not* work on clang 6 on ARM64.
-  AS_IF([test $sync_bool_compare_and_swap_128_result -eq 1],
-        [AC_MSG_CHECKING([if __sync_bool_compare_and_swap works])
-         AC_RUN_IFELSE([AC_LANG_SOURCE(OPAL_SYNC_BOOL_COMPARE_AND_SWAP_TEST_SOURCE)],
-              [AC_MSG_RESULT([yes])],
-              [sync_bool_compare_and_swap_128_result=0
-               AC_MSG_RESULT([no])],
-              [AC_MSG_RESULT([cannot test -- assume yes (cross compiling)])])
-         ])
-
   AC_DEFINE_UNQUOTED([OPAL_HAVE_SYNC_BUILTIN_CSWAP_INT128],
         [$sync_bool_compare_and_swap_128_result],
         [Whether the __sync builtin atomic compare and swap supports 128-bit values])
@@ -267,17 +278,6 @@ AC_DEFUN([OPAL_CHECK_GCC_BUILTIN_CSWAP_INT128], [
       [atomic_compare_exchange_n_128_result=1],
       [atomic_compare_exchange_n_128_result=0])
 
-  # If we have it, try it, and make sure it works.  As of Aug 2018, we
-  # know that it does *not* work on clang 6 on ARM64.
-  AS_IF([test $atomic_compare_exchange_n_128_result -eq 1],
-        [AC_MSG_CHECKING([if __atomic_compare_exchange_n works])
-         AC_RUN_IFELSE([AC_LANG_SOURCE(OPAL_ATOMIC_COMPARE_EXCHANGE_N_TEST_SOURCE)],
-              [AC_MSG_RESULT([yes])],
-              [atomic_compare_exchange_n_128_result=0
-               AC_MSG_RESULT([no])],
-              [AC_MSG_RESULT([cannot test -- assume yes (cross compiling)])])
-         ])
-
   # If we have it and it works, check to make sure it is always lock
   # free.
   AS_IF([test $atomic_compare_exchange_n_128_result -eq 1],