Port input completion provider to Rego (#1505)

Tiny one, but it's honest work!

Signed-off-by: Anders Eknert <anders@styra.com>

Author: anderseknert

bundle/regal/lsp/completion/providers/input/input.rego

@@ -0,0 +1,45 @@
+# METADATA
+# description: provides completion suggestions for the `input` keyword where applicable
+package regal.lsp.completion.providers.input
+
+import data.regal.lsp.completion.kind
+import data.regal.lsp.completion.location
+
+# METADATA
+# description: all completion suggestions for the input keyword
+items contains item if {
+	position := location.to_position(input.regal.context.location)
+	line := input.regal.file.lines[position.line]
+
+	line != ""
+	location.in_rule_body(line)
+
+	word := location.word_at(line, input.regal.context.location.col)
+
+	startswith("input", word.text)
+
+	item := {
+		"label": "input",
+		"kind": kind.keyword,
+		"detail": "input document",
+		"textEdit": {
+			"range": location.word_range(word, position),
+			"newText": "input",
+		},
+		"documentation": {
+			"kind": "markdown",
+			"value": _doc,
+		},
+	}
+}
+
+_doc := `# input
+
+'input' refers to the input document being evaluated.
+It is a special keyword that allows you to access the data sent to OPA at evaluation time.
+
+To see more examples of how to use 'input', check out the
+[policy language documentation](https://www.openpolicyagent.org/docs/latest/policy-language/).
+
+You can also experiment with input in the [Rego Playground](https://play.openpolicyagent.org/).
+`

bundle/regal/lsp/completion/providers/input/input_test.rego

@@ -0,0 +1,36 @@
+package regal.lsp.completion.providers.input_test
+
+import data.regal.lsp.completion.providers.input as provider
+import data.regal.lsp.completion.providers.test_utils as util
+
+test_input_completion_on_typing if {
+	policy := `package policy
+
+allow if {
+	i
+}`
+	items := provider.items with input as util.input_with_location(policy, {"row": 4, "col": 3})
+
+	items == {{
+		"detail": "input document",
+		"documentation": {
+			"kind": "markdown",
+			"value": provider._doc,
+		},
+		"kind": 14,
+		"label": "input",
+		"textEdit": {
+			"newText": "input",
+			"range": {
+				"end": {
+					"character": 2,
+					"line": 3,
+				},
+				"start": {
+					"character": 1,
+					"line": 3,
+				},
+			},
+		},
+	}}
+}

internal/lsp/completions/manager.go

@@ -36,7 +36,6 @@ func NewDefaultManager(ctx context.Context, c *cache.Cache, store storage.Store)
 	m.RegisterProvider(&providers.PackageRefs{})
 	m.RegisterProvider(&providers.RuleHead{})
 	m.RegisterProvider(&providers.RuleHeadKeyword{})
-	m.RegisterProvider(&providers.Input{})
 
 	m.RegisterProvider(providers.NewPolicy(ctx, store))
 

internal/lsp/completions/providers/input.go

@@ -140,7 +140,7 @@ allow if {
 		labels = append(labels, item.Label)
 	}
 
-	expected := []string{"example", "example.foo"}
+	expected := []string{"input", "example", "example.foo"}
 	if !slices.Equal(expected, labels) {
 		t.Fatalf("expected %v, got %v", expected, labels)
 	}