lsp/completions: Handle hyphenated package names

Fixes #1391

Signed-off-by: Charlie Egan <charlie@styra.com>

Author: Charlie Egan

bundle/regal/lsp/completion/providers/packagename/packagename.rego

@@ -42,10 +42,39 @@ _base(path) := substring(path, 0, regal.last(indexof_n(path, "/")))
 _suggestions(dir, text) := [path |
 	parts := split(dir, ".")
 	len_p := count(parts)
+
 	some n in numbers.range(0, len_p)
 
-	path := concat(".", array.slice(parts, n, len_p))
+	formatted_parts := [p |
+		some index, part in array.slice(parts, n, len_p)
+		p := _format_part(part, contains(part, "-"))
+	]
+
+	path := concat("", [p |
+		some index, part in formatted_parts
+		p := _delimit_part(part, array.slice(formatted_parts, index + 1, index + 2))
+	])
+
 	path != ""
 
+	# it's not valid Rego to have a hypenated first part
+	not startswith(path, `[""`)
+
 	startswith(path, text)
 ]
+
+_format_part(part, false) := part
+_format_part(part, true) := sprintf(`["%s"]`, [part])
+
+_delimit_part(part, next_part) := delimited_part if {
+	next_part != []
+	not startswith(next_part[0], "[")
+	delimited_part := sprintf("%s.", [part])
+}
+
+_delimit_part(part, next_part) := part if {
+	next_part != []
+	startswith(next_part[0], "[")
+}
+
+_delimit_part(part, next_part) := part if next_part == []

bundle/regal/lsp/completion/providers/packagename/packagename_test.rego

@@ -135,6 +135,64 @@ test_package_name_completion_on_typing_multiple_suggestions_when_invoked if {
 	}
 }
 
+test_package_name_quoted if {
+	policy := `package f`
+	provider_input := {"regal": {
+		"file": {
+			"name": "/Users/joe/foo/bar/baz-are/foo/baz-are/foo/p.rego",
+			"lines": split(policy, "\n"),
+		},
+		"context": {
+			"workspace_root": "/Users/joe/policy",
+			"location": {
+				"row": 1,
+				"col": 10,
+			},
+		},
+		"environment": {"path_separator": "/"},
+	}}
+
+	items := provider.items with input as provider_input
+	items == {
+		{
+			"detail": "suggested package name based on directory structure",
+			"kind": 19,
+			"label": "foo.bar[\"baz-are\"].foo[\"baz-are\"].foo",
+			"textEdit": {
+				"newText": "foo.bar[\"baz-are\"].foo[\"baz-are\"].foo\n\n",
+				"range": {
+					"end": {"character": 9, "line": 0},
+					"start": {"character": 8, "line": 0},
+				},
+			},
+		},
+		{
+			"detail": "suggested package name based on directory structure",
+			"kind": 19,
+			"label": "foo",
+			"textEdit": {
+				"newText": "foo\n\n",
+				"range": {
+					"end": {"character": 9, "line": 0},
+					"start": {"character": 8, "line": 0},
+				},
+			},
+		},
+		{
+			"detail": "suggested package name based on directory structure",
+			"kind": 19,
+			"label": "foo[\"baz-are\"].foo",
+			"textEdit": {
+				"newText": "foo[\"baz-are\"].foo\n\n",
+				"range": {
+					"end": {"character": 9, "line": 0},
+					"start": {"character": 8, "line": 0},
+				},
+			},
+		},
+	}
+}
+
 test_build_suggestions if {
 	provider._suggestions("foo.bar.baz", "foo") == ["foo.bar.baz"]
 	provider._suggestions("foo.bar.baz", "bar") == ["bar.baz"]