opentelemetry-java-instrumentation/instrumentation/jms/jms-1.1/javaagent/build.gradle.kts at 923ba334882040735c25253127f12855e8e1c9d4 · open-telemetry/opentelemetry-java-instrumentation · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
plugins {
  id("otel.javaagent-instrumentation")
}

muzzle {
  pass {
    group.set("javax.jms")
    module.set("jms-api")
    versions.set("(,)")
  }
  pass {
    group.set("javax.jms")
    module.set("javax.jms-api")
    versions.set("(,)")
  }
  pass {
    group.set("jakarta.jms")
    module.set("jakarta.jms-api")
    versions.set("(,3)")
    assertInverse.set(true)
  }
}

dependencies {
  implementation(project(":instrumentation:jms:jms-common-1.1:javaagent"))
  bootstrap(project(":instrumentation:jms:jms-common-1.1:bootstrap"))

  compileOnly("javax.jms:jms-api:1.1-rev-1")

  testImplementation("org.apache.activemq:activemq-client:5.16.5")

  testInstrumentation(project(":instrumentation:jms:jms-3.0:javaagent"))
}

testing {
  suites {
    register<JvmTestSuite>("unitTests") {
      dependencies {
        implementation(project())
        implementation(project(":javaagent-bootstrap"))
        implementation(project(":instrumentation:jms:jms-common-1.1:bootstrap"))
        implementation(project(":instrumentation:jms:jms-common-1.1:javaagent"))
        implementation(project(":javaagent-extension-api"))
        implementation("javax.jms:jms-api:1.1-rev-1")
      }
    }

    register<JvmTestSuite>("jms2Test") {
      dependencies {
        implementation("org.hornetq:hornetq-jms-client:2.4.7.Final")
        implementation("org.hornetq:hornetq-jms-server:2.4.7.Final")
      }

      targets {
        all {
          testTask.configure {
            jvmArgs("-Dotel.instrumentation.common.messaging.experimental.receive-telemetry.enabled=true")
            systemProperty(
              "metadataConfig",
              "otel.instrumentation.common.messaging.experimental.receive-telemetry.enabled=true",
            )
          }
        }
      }
    }
  }
}

tasks {
  withType<Test>().configureEach {
    usesService(gradle.sharedServices.registrations["testcontainersBuildService"].service)
  }

  val testReceiveSpansDisabled = register<Test>("testReceiveSpansDisabled") {
    testClassesDirs = sourceSets.test.get().output.classesDirs
    classpath = sourceSets.test.get().runtimeClasspath

    filter {
      includeTestsMatching("Jms1SuppressReceiveSpansTest")
    }
    include("**/Jms1SuppressReceiveSpansTest.*")
  }

  test {
    filter {
      excludeTestsMatching("Jms1SuppressReceiveSpansTest")
    }
    jvmArgs("-Dotel.instrumentation.common.messaging.experimental.receive-telemetry.enabled=true")
    systemProperty(
      "metadataConfig",
      "otel.instrumentation.common.messaging.experimental.receive-telemetry.enabled=true",
    )
  }

  check {
    dependsOn(
      testing.suites,
      testReceiveSpansDisabled,
    )
  }
}

configurations.configureEach {
  // this doesn't exist in maven central, and doesn't seem to be needed anyways
  // included from org.hornetq:hornetq-jms-server:2.4.7.Final
  exclude("org.jboss.naming", "jnpserver")
}