build.gradle.kts

import com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar

plugins {
  id("otel.javaagent-instrumentation")
}

muzzle {
  pass {
    group.set("software.amazon.awssdk")
    module.set("aws-core")
    versions.set("[2.2.0,)")
    skip("2.17.200") // broken AWS SDK release: sdk-core 2.17.200 was not published
    assertInverse.set(true)
    // Used by all SDK services, the only case it isn't is an SDK extension such as a custom HTTP
    // client, which is not target of instrumentation anyways.
    extraDependency("software.amazon.awssdk:protocol-core")

    excludeInstrumentationModule("io.opentelemetry.javaagent.instrumentation.awssdk.v2_2.BedrockRuntimeInstrumentationModule")
    excludeInstrumentationModule("io.opentelemetry.javaagent.instrumentation.awssdk.v2_2.SqsInstrumentationModule")
    excludeInstrumentationModule("io.opentelemetry.javaagent.instrumentation.awssdk.v2_2.SnsInstrumentationModule")
    excludeInstrumentationModule("io.opentelemetry.javaagent.instrumentation.awssdk.v2_2.LambdaInstrumentationModule")
  }

  fail {
    group.set("software.amazon.awssdk")
    module.set("aws-core")
    versions.set("[2.2.0,)")
    // Used by all SDK services, the only case it isn't is an SDK extension such as a custom HTTP
    // client, which is not target of instrumentation anyways.
    extraDependency("software.amazon.awssdk:protocol-core")

    // "fail" asserts that *all* the instrumentation modules fail to load, but the core one is
    // actually expected to succeed, so exclude it from checks.
    excludeInstrumentationModule("io.opentelemetry.javaagent.instrumentation.awssdk.v2_2.AwsSdkInstrumentationModule")
  }

  pass {
    group.set("software.amazon.awssdk")
    module.set("sqs")
    versions.set("[2.2.0,)")
    assertInverse.set(true)
    // Used by all SDK services, the only case it isn't is an SDK extension such as a custom HTTP
    // client, which is not target of instrumentation anyways.
    extraDependency("software.amazon.awssdk:protocol-core")

    excludeInstrumentationModule("io.opentelemetry.javaagent.instrumentation.awssdk.v2_2.BedrockRuntimeInstrumentationModule")
    excludeInstrumentationModule("io.opentelemetry.javaagent.instrumentation.awssdk.v2_2.SnsInstrumentationModule")
    excludeInstrumentationModule("io.opentelemetry.javaagent.instrumentation.awssdk.v2_2.LambdaInstrumentationModule")
  }

  pass {
    group.set("software.amazon.awssdk")
    module.set("sns")
    versions.set("[2.2.0,)")
    // Used by all SDK services, the only case it isn't is an SDK extension such as a custom HTTP
    // client, which is not target of instrumentation anyways.
    extraDependency("software.amazon.awssdk:protocol-core")

    excludeInstrumentationModule("io.opentelemetry.javaagent.instrumentation.awssdk.v2_2.BedrockRuntimeInstrumentationModule")
    excludeInstrumentationModule("io.opentelemetry.javaagent.instrumentation.awssdk.v2_2.SqsInstrumentationModule")
    excludeInstrumentationModule("io.opentelemetry.javaagent.instrumentation.awssdk.v2_2.LambdaInstrumentationModule")
  }
  pass {
    group.set("software.amazon.awssdk")
    module.set("lambda")
    versions.set("[2.17.0,)")
    skip("2.17.200") // broken AWS SDK release: sdk-core 2.17.200 was not published
    // Used by all SDK services, the only case it isn't is an SDK extension such as a custom HTTP
    // client, which is not target of instrumentation anyways.
    extraDependency("software.amazon.awssdk:protocol-core")

    excludeInstrumentationModule("io.opentelemetry.javaagent.instrumentation.awssdk.v2_2.BedrockRuntimeInstrumentationModule")
    excludeInstrumentationModule("io.opentelemetry.javaagent.instrumentation.awssdk.v2_2.SqsInstrumentationModule")
    excludeInstrumentationModule("io.opentelemetry.javaagent.instrumentation.awssdk.v2_2.SnsInstrumentationModule")
  }
  pass {
    group.set("software.amazon.awssdk")
    module.set("bedrockruntime")
    versions.set("[2.25.63,)")
    // Used by all SDK services, the only case it isn't is an SDK extension such as a custom HTTP
    // client, which is not target of instrumentation anyways.
    extraDependency("software.amazon.awssdk:protocol-core")

    excludeInstrumentationModule("io.opentelemetry.javaagent.instrumentation.awssdk.v2_2.LambdaInstrumentationModule")
    excludeInstrumentationModule("io.opentelemetry.javaagent.instrumentation.awssdk.v2_2.SqsInstrumentationModule")
    excludeInstrumentationModule("io.opentelemetry.javaagent.instrumentation.awssdk.v2_2.SnsInstrumentationModule")
  }
}

dependencies {
  implementation(project(":instrumentation:aws-sdk:aws-sdk-2.2:library"))

  library("software.amazon.awssdk:aws-core:2.2.0")
  library("software.amazon.awssdk:sqs:2.2.0")

  // Don't use library to make sure base test is run with the floor version.
  // bedrock runtime is tested separately in testBedrockRuntime.
  // First release with Converse API
  compileOnly("software.amazon.awssdk:bedrockruntime:2.25.63")

  testImplementation(project(":instrumentation:aws-sdk:aws-sdk-2.2:testing"))
  testImplementation("io.opentelemetry.contrib:opentelemetry-aws-xray-propagator")

  // Make sure these don't add HTTP headers
  testInstrumentation(project(":instrumentation:apache-httpclient:apache-httpclient-4.0:javaagent"))
  testInstrumentation(project(":instrumentation:apache-httpclient:apache-httpclient-5.0:javaagent"))
  testInstrumentation(project(":instrumentation:aws-sdk:aws-sdk-1.11:javaagent"))
  testInstrumentation(project(":instrumentation:netty:netty-4.1:javaagent"))

  testLibrary("software.amazon.awssdk:dynamodb:2.2.0")
  testLibrary("software.amazon.awssdk:ec2:2.2.0")
  testLibrary("software.amazon.awssdk:kinesis:2.2.0")
  testLibrary("software.amazon.awssdk:lambda:2.2.0")
  testLibrary("software.amazon.awssdk:rds:2.2.0")
  testLibrary("software.amazon.awssdk:s3:2.2.0")
  testLibrary("software.amazon.awssdk:ses:2.2.0")
  testLibrary("software.amazon.awssdk:secretsmanager:2.2.0")
  testLibrary("software.amazon.awssdk:sfn:2.2.0")
  testLibrary("software.amazon.awssdk:sns:2.2.0")
  testLibrary("software.amazon.awssdk:sqs:2.2.0")
}

testing {
  suites {
    register<JvmTestSuite>("s3PresignerTest") {
      dependencies {
        val version = baseVersion("2.10.12").orLatest()
        implementation("software.amazon.awssdk:s3:$version")
        implementation(project(":instrumentation:aws-sdk:aws-sdk-2.2:library"))
      }
    }

    register<JvmTestSuite>("s3CrtTest") {
      dependencies {
        implementation("software.amazon.awssdk:s3:${baseVersion("2.27.21").orLatest()}")
        implementation("software.amazon.awssdk.crt:aws-crt:${baseVersion("0.30.11").orLatest()}")
        implementation(project(":instrumentation:aws-sdk:aws-sdk-2.2:library"))
        implementation("org.testcontainers:testcontainers-localstack")
      }
    }

    register<JvmTestSuite>("testBedrockRuntime") {
      dependencies {
        implementation(project(":instrumentation:aws-sdk:aws-sdk-2.2:testing"))
        // 2.25.63 is the first release with Converse API
        val version = baseVersion("2.25.63").orLatest()
        implementation("software.amazon.awssdk:bedrockruntime:$version")
      }
    }

    register<JvmTestSuite>("testRdsData") {
      dependencies {
        implementation(project(":instrumentation:aws-sdk:aws-sdk-2.2:testing"))
        val version = baseVersion("2.5.54").orLatest()
        implementation("software.amazon.awssdk:rdsdata:$version")
      }
    }
  }
}

tasks {
  val testExperimentalSqs = register<Test>("testExperimentalSqs") {
    testClassesDirs = sourceSets.test.get().output.classesDirs
    classpath = sourceSets.test.get().runtimeClasspath

    filter.includeTestsMatching("Aws2SqsTracingTest")
    systemProperty("otel.instrumentation.aws-sdk.experimental-use-propagator-for-messaging", "true")
    systemProperty("otel.instrumentation.common.messaging.experimental.receive-telemetry.enabled", "true")
  }

  val testReceiveSpansDisabled = register<Test>("testReceiveSpansDisabled") {
    testClassesDirs = sourceSets.test.get().output.classesDirs
    classpath = sourceSets.test.get().runtimeClasspath

    filter {
      includeTestsMatching("Aws2SqsSuppressReceiveSpansTest")
    }
    include("**/Aws2SqsSuppressReceiveSpansTest.*")
  }

  test {
    filter {
      excludeTestsMatching("Aws2SqsSuppressReceiveSpansTest")
    }
  }

  withType<Test>().configureEach {
    usesService(gradle.sharedServices.registrations["testcontainersBuildService"].service)
    systemProperty("testLatestDeps", otelProps.testLatestDeps)
  }

  val testExperimentalAttributes = register<Test>("testExperimentalAttributes") {
    testClassesDirs = sourceSets.test.get().output.classesDirs
    classpath = sourceSets.test.get().runtimeClasspath

    filter.excludeTestsMatching("Aws2SqsSuppressReceiveSpansTest")
    systemProperty("otel.instrumentation.aws-sdk.experimental-span-attributes", "true")
    systemProperty(
      "metadataConfig",
      "otel.instrumentation.aws-sdk.experimental-span-attributes=true",
    )
  }

  val testIndividualHttpErrors = register<Test>("testIndividualHttpErrors") {
    testClassesDirs = sourceSets.test.get().output.classesDirs
    classpath = sourceSets.test.get().runtimeClasspath

    filter.includeTestsMatching("Aws2ClientRecordHttpErrorTest")
    systemProperty("otel.instrumentation.aws-sdk.experimental-record-individual-http-error", "true")
    systemProperty(
      "metadataConfig",
      "otel.instrumentation.aws-sdk.experimental-record-individual-http-error=true",
    )
  }

  val testReceiveTelemetry = register<Test>("testReceiveTelemetry") {
    testClassesDirs = sourceSets.test.get().output.classesDirs
    classpath = sourceSets.test.get().runtimeClasspath
    filter.includeTestsMatching("Aws2SqsTracingTest")
    systemProperty("otel.instrumentation.aws-sdk.experimental-span-attributes", "true")
    systemProperty("otel.instrumentation.common.messaging.experimental.receive-telemetry.enabled", "true")
    systemProperty(
      "metadataConfig",
      "otel.instrumentation.aws-sdk.experimental-span-attributes=true," +
        "otel.instrumentation.common.messaging.experimental.receive-telemetry.enabled=true",
    )
  }

  val testBedrockRuntimeCaptureMessageContent = register<Test>("testBedrockRuntimeCaptureMessageContent") {
    testClassesDirs = sourceSets["testBedrockRuntime"].output.classesDirs
    classpath = sourceSets["testBedrockRuntime"].runtimeClasspath

    systemProperty("otel.instrumentation.genai.capture-message-content", "true")
    systemProperty("metadataConfig", "otel.instrumentation.genai.capture-message-content=true")
  }

  val testRdsDataExperimentalAttributes = register<Test>("testRdsDataExperimentalAttributes") {
    testClassesDirs = sourceSets["testRdsData"].output.classesDirs
    classpath = sourceSets["testRdsData"].runtimeClasspath

    systemProperty("otel.instrumentation.aws-sdk.experimental-span-attributes", "true")
  }

  check {
    dependsOn(
      testing.suites,
      testExperimentalSqs,
      testReceiveSpansDisabled,
      testExperimentalAttributes,
      testIndividualHttpErrors,
      testReceiveTelemetry,
      testBedrockRuntimeCaptureMessageContent,
      testRdsDataExperimentalAttributes,
    )
  }

  withType<ShadowJar>().configureEach {
    mergeServiceFiles {
      include("software/amazon/awssdk/global/handlers/execution.interceptors")
    }
    // mergeServiceFiles requires that duplicate strategy is set to include
    filesMatching("software/amazon/awssdk/global/handlers/execution.interceptors") {
      duplicatesStrategy = DuplicatesStrategy.INCLUDE
    }
  }

  if (otelProps.denyUnsafe) {
    // Aws2SqsTracingTest uses org.elasticmq:elasticmq-rest-sqs_2.13 that uses unsafe. Future
    // versions are likely to fix this.
    withType<Test>().configureEach {
      enabled = false
    }
  }
}