Spin-up Miniflux through Nix devenv

[dminca]

Hi everyone 👋
just bumped into this awesome project couple of days ago and wanted to try it out.

However, as I don't use any containers locally because I consider them overhead, decided to boot this up via devenv since I'm already using Nix Flake on all my stations.

So the journey begins, I wrote myself a small program

{
  pkgs,
  lib,
  config,
  ...
}:
{
  processes.miniflux = {
    exec = lib.getExe pkgs.miniflux;
    process-compose = {
      depends_on = {
        postgres = {
          condition = "process_healthy";
        };
      };
      readiness_probe = {
        exec.command = "${lib.getExe pkgs.netcat} -z 127.0.0.1 8080";
        initial_delay_seconds = 2;
        period_seconds = 10;
        timeout_seconds = 2;
        success_threshold = 1;
        failure_threshold = 3;
      };
    };
  };
  packages = [
    pkgs.miniflux
  ];

  # https://devenv.sh/services/
  services.postgres = {
    enable = true;
    listen_addresses = "127.0.0.1";
  };
  env = {
    ADMIN_PASSWORD = "123456";
    CREATE_ADMIN=1;
    ADMIN_USERNAME="admin";
    RUN_MIGRATIONS=1;
    DATABASE_URL="user=<local-uid> dbname=postgres sslmode=disable";
    LISTEN_ADDR="0.0.0.0:8080";
  };
  enterTest = ''
    wait_for_port 5432
  '';
  # See full reference at https://devenv.sh/reference/options/
}

And this replicates exactly what docker-compose is trying to do however without using any containers at all, rather installing & running these processes in something like a chroot jail.

Once you

1. drop in the devenv shell
2. spin-up the processes devenv up

You're all set up and can simply open http://localhost:8080 on your browser and try the app out.

Screenshots

References

• git repo
• devenv