Update build-system to support building wheel using manylinux1

As discussed in [1], starting with CMake 3.14.0, version of libuv
bundled in CMake doesn't support being built with manylinux1.

This commit explicitly downloads an older version of libuv that can
be built on system with older kernel.

To avoid link error like the following, -lrt linker flag is specified:

  /work/libuv-install/lib64/libuv_a.a(linux-core.c.o): In function `uv__hrtime':
  linux-core.c:(.text+0xb58): undefined reference to `clock_getres'
  linux-core.c:(.text+0xbab): undefined reference to `clock_gettime'
  /work/libuv-install/lib64/libuv_a.a(linux-core.c.o): In function `uv_uptime':
  linux-core.c:(.text+0xd91): undefined reference to `clock_gettime'
  linux-core.c:(.text+0xda7): undefined reference to `clock_gettime'
  collect2: error: ld returned 1 exit status


See #78

[1] https://gitlab.kitware.com/cmake/cmake/issues/19311

Author: jcfr

CMakeLists.txt

@@ -155,53 +155,105 @@ if(CMakePythonDistributions_SUPERBUILD)
     # CMakeProject_BINARY_DIR
     #
     if(NOT DEFINED CMakeProject_BINARY_DIR)
-      set(CMakeProject_BINARY_DIR ${CMAKE_BINARY_DIR}/CMakeProject-build)
 
-      set(_cmake_cache_args)
+      # cache arguments common to LibUV and CMake
+      set(_common_cache_args)
       if(DEFINED CMAKE_BUILD_TYPE)
-        list(APPEND _cmake_cache_args
+        list(APPEND _common_cache_args
           -DCMAKE_BUILD_TYPE:STRING=${CMAKE_BUILD_TYPE}
           )
       endif()
-      if(DEFINED OPENSSL_ROOT_DIR)
-        list(APPEND _cmake_cache_args
-          -DOPENSSL_ROOT_DIR:PATH=${OPENSSL_ROOT_DIR}
-          )
-        message(STATUS "SuperBuild -   CMakeProject-build - OPENSSL_ROOT_DIR: ${OPENSSL_ROOT_DIR}")
-      endif()
       foreach(var_name IN ITEMS
         CMAKE_BUILD_PARALLEL_LEVEL
         CMAKE_JOB_POOLS
         CMAKE_JOB_POOL_COMPILE
         CMAKE_JOB_POOL_LINK
         )
         if(DEFINED ${var_name})
-          list(APPEND _cmake_cache_args
+          list(APPEND _common_cache_args
             -D${var_name}:STRING=${${var_name}}
             )
           message(STATUS "SuperBuild -   CMakeProject-build - ${var_name}: ${${var_name}}")
         endif()
       endforeach()
 
+      set(_common_args )
+      if(UNIX AND NOT APPLE)
+        # Since CMAKE_C_FLAGS and CMAKE_EXE_LINKER_FLAGS arguments contain spaces, we generate an initial
+        # cache file.
+        file(WRITE "${CMAKE_BINARY_DIR}/initial-cache.txt"
+"set(CMAKE_C_FLAGS \"-D_POSIX_C_SOURCE=199506L -D_POSIX_SOURCE=1 -D_SVID_SOURCE=1 -D_BSD_SOURCE=1\" CACHE STRING \"Initial cache\" FORCE)
+set(CMAKE_EXE_LINKER_FLAGS \"-static-libstdc++ -static-libgcc -lrt\" CACHE STRING \"Initial cache\" FORCE)
+")
+        set(_common_args
+          CMAKE_ARGS -C "${CMAKE_BINARY_DIR}/initial-cache.txt"
+          )
+      endif()
+
+      # cache arguments for CMake
+      set(_cmake_cache_args)
+
+      # libuv
+      if(UNIX AND NOT APPLE)
+        set(LibUV_SOURCE_DIR ${CMAKE_BINARY_DIR}/LibUV-src)
+        set(LibUV_BINARY_DIR ${CMAKE_BINARY_DIR}/LibUV-build)
+        set(LibUV_INSTALL_DIR ${CMAKE_BINARY_DIR}/LibUV-install)
+
+        ExternalProject_add(LibUV
+          SOURCE_DIR ${LibUV_SOURCE_DIR}
+          BINARY_DIR ${LibUV_BINARY_DIR}
+          URL "https://dist.libuv.org/dist/v1.23.0/libuv-v1.23.0.tar.gz"
+          URL_HASH "SHA256=d1746d324dea973d9f4c7ff40ba9cf60556c0bae9a92ad970568211b0e3bce27"
+          ${_common_args}
+          CMAKE_CACHE_ARGS
+            ${_common_cache_args}
+            -DCMAKE_INSTALL_PREFIX:PATH=${LibUV_INSTALL_DIR}
+          USES_TERMINAL_CONFIGURE 1
+          USES_TERMINAL_BUILD 1
+          ${ep_log_configure_build_args}
+          INSTALL_DIR ${LibUV_INSTALL_DIR}
+          )
+        list(APPEND _cmake_cache_args
+          -DCMAKE_USE_SYSTEM_LIBRARY_LIBUV:BOOL=ON
+          -DLibUV_LIBRARY:FILEPATH=${LibUV_INSTALL_DIR}/lib64/libuv_a.a
+          -DLibUV_INCLUDE_DIR:PATH=${LibUV_INSTALL_DIR}/include
+          )
+      else()
+        cpd_ExternalProject_Add_Empty(LibUV "")
+      endif()
+
+      # cmake
+      set(CMakeProject_BINARY_DIR ${CMAKE_BINARY_DIR}/CMakeProject-build)
+
+      if(DEFINED OPENSSL_ROOT_DIR)
+        list(APPEND _cmake_cache_args
+          -DOPENSSL_ROOT_DIR:PATH=${OPENSSL_ROOT_DIR}
+          )
+        message(STATUS "SuperBuild -   CMakeProject-build - OPENSSL_ROOT_DIR: ${OPENSSL_ROOT_DIR}")
+      endif()
+
       ExternalProject_add(CMakeProject-build
         SOURCE_DIR ${CMakeProject_SOURCE_DIR}
         BINARY_DIR ${CMakeProject_BINARY_DIR}
         DOWNLOAD_COMMAND ""
         UPDATE_COMMAND ""
         BUILD_ALWAYS 1
+        ${_common_args}
         CMAKE_CACHE_ARGS
           -DBUILD_CursesDialog:BOOL=OFF
           -DCMAKE_USE_OPENSSL:BOOL=ON
           -DBUILD_TESTING:BOOL=OFF
           -DCMake_INSTALL_DEPENDENCIES:BOOL=ON
           -DCMAKE_INSTALL_MESSAGE:STRING=NEVER
+          ${_common_cache_args}
           ${_cmake_cache_args}
         USES_TERMINAL_CONFIGURE 1
         USES_TERMINAL_BUILD 1
         ${ep_log_configure_build_args}
         INSTALL_COMMAND ""
         DEPENDS
           CMakeProject-src-download
+          LibUV
         )
 
         find_program(STRIP_EXECUTABLE strip)