Add lit tests

Author: weliveindetail

CMakeLists.txt

@@ -25,6 +25,10 @@ if(LLVM_BUILD_MAIN_SRC_DIR AND EXISTS "${LLVM_BUILD_MAIN_SRC_DIR}" AND UNIX)
   )
 endif()
 
+# Import extra CMake helpers from LLVM
+list(APPEND CMAKE_MODULE_PATH ${LLVM_DIR})
+include(AddLLVM)
+
 if(NOT CMAKE_BUILD_TYPE)
   message(STATUS "No explicit CMAKE_BUILD_TYPE provided; JitFromScratch defaults to the build type of LLVM")
   set(CMAKE_BUILD_TYPE ${LLVM_BUILD_TYPE} CACHE STRING "" FORCE)
@@ -74,4 +78,4 @@ add_custom_target(run
   COMMENT "Running JitFromScratch"
 )
 
-message("")
+add_subdirectory(test)

test/CMakeLists.txt

@@ -0,0 +1,61 @@
+# Used in add_lit_target to find the llvm-lit driver
+set(LLVM_RUNTIME_OUTPUT_INTDIR ${LLVM_TOOLS_BINARY_DIR})
+
+# Show test output for failures
+list(APPEND LLVM_LIT_ARGS -v)
+
+# lit driver and config files are Python scripts
+set(Python_ADDITIONAL_VERSIONS 3.7 3.6 3.5 2.7)
+include(FindPythonInterp)
+
+if(NOT PYTHONINTERP_FOUND OR ${PYTHON_VERSION_STRING} VERSION_LESS 2.7)
+  string(CONCAT error
+    "Python 2.7 or newer is required for tests. Please install "
+    "Python or specify the PYTHON_EXECUTABLE CMake variable. "
+  )
+endif()
+
+if(NOT TARGET FileCheck)
+  if(LLVM_BUILD_MAIN_SRC_DIR)
+    string(CONCAT error ${error}
+      "FileCheck is required for tests. Make sure the "
+      "${LLVM_TOOLS_BINARY_DIR}/FileCheck executable was built. "
+      "Make sure LLVM has LLVM_BUILD_UTILS=ON (default). "
+    )
+  else()
+    string(CONCAT error ${error}
+      "The installed LLVM does not provide the FileCheck executable. This is "
+      "the default for distribution packages (the distributor can change that "
+      "by passing LLVM_INSTALL_UTILS=ON). Without FileCheck lit tests "
+      "cannot run. Build LLVM yourself from source and point JitFromScratch to "
+      "the build-tree to enable tests. "
+    )
+  endif()
+endif()
+
+if(error)
+  message(WARNING "Failed to configure tests: ${error}")
+  add_custom_target(check
+    COMMAND ${CMAKE_COMMAND} -E echo
+    COMMENT "Cannot run tests"
+  )
+  # We still want to build the executable.
+  add_dependencies(check JitFromScratch)
+else()
+  set(LLVM_DEFAULT_EXTERNAL_LIT ${LLVM_TOOLS_BINARY_DIR}/llvm-lit
+      CACHE PATH "Path to llvm-lit")
+
+  configure_lit_site_cfg(
+    ${CMAKE_CURRENT_SOURCE_DIR}/lit.site.cfg.py.in
+    ${CMAKE_CURRENT_BINARY_DIR}/lit.site.cfg.py
+    MAIN_CONFIG
+    ${CMAKE_CURRENT_SOURCE_DIR}/lit.cfg.py
+  )
+
+  add_lit_target(check "Running tests"
+    ${CMAKE_CURRENT_BINARY_DIR}
+    DEPENDS JitFromScratch FileCheck
+  )
+endif()
+
+message("")

test/lit.cfg.py

@@ -0,0 +1,15 @@
+import os
+
+import lit.util
+import lit.formats
+from lit.llvm import llvm_config
+
+config.name = 'JitFromScratch'
+
+config.test_format = lit.formats.ShTest()
+config.test_source_root = os.path.dirname(__file__)
+config.suffixes = ['.test']
+
+# Add binary directories for JitFromScratch and FileCheck executables
+llvm_config.with_environment('PATH', config.jitfromscratch_build_dir, append_path=True)
+llvm_config.with_environment('PATH', config.llvm_tools_dir, append_path=True)

test/lit.site.cfg.py.in

@@ -0,0 +1,14 @@
+@LIT_SITE_CFG_IN_HEADER@
+
+import sys
+
+config.llvm_tools_dir = "@LLVM_TOOLS_DIR@"
+config.lit_tools_dir = "@LLVM_LIT_TOOLS_DIR@"
+config.python_executable = "@PYTHON_EXECUTABLE@"
+config.jitfromscratch_build_dir = "@CMAKE_BINARY_DIR@/@CMAKE_CFG_INTDIR@"
+
+import lit.llvm
+lit.llvm.initialize(lit_config, config)
+
+# Let the main config do the real work.
+lit_config.load_config(config, "@CMAKE_SOURCE_DIR@/test/lit.cfg.py")

test/stdout.test

@@ -0,0 +1,3 @@
+# Check that integer distances are printed as expected
+# RUN: JitFromScratch | FileCheck %s
+# CHECK: Integer Distances: 3, 0, 3