Wire up LLVM

Author: weliveindetail

CMakeLists.txt

@@ -8,14 +8,52 @@ if(NOT CMAKE_TOOLCHAIN_FILE)
   include(DefaultToolchain)
 endif()
 
+include(LLVM)
+
+if(LLVM_ENABLE_RTTI)
+  message(WARNING "LLVM built with RTTI; enabling it for JitFromScratch to avoid quirks")
+  set(rtti_flags ${HOST_ENABLE_RTTI})
+else()
+  set(rtti_flags ${HOST_DISABLE_RTTI})
+endif()
+
+# If we have a LLVM source-tree, symlink it for debug source maps
+if(LLVM_BUILD_MAIN_SRC_DIR AND EXISTS "${LLVM_BUILD_MAIN_SRC_DIR}" AND UNIX)
+  execute_process(
+    COMMAND ${CMAKE_COMMAND} -E create_symlink ${LLVM_BUILD_MAIN_SRC_DIR}
+                                               ${CMAKE_BINARY_DIR}/llvm-project
+  )
+endif()
+
+if(NOT CMAKE_BUILD_TYPE)
+  message(STATUS "No explicit CMAKE_BUILD_TYPE provided; JitFromScratch defaults to the build type of LLVM")
+  set(CMAKE_BUILD_TYPE ${LLVM_BUILD_TYPE} CACHE STRING "" FORCE)
+elseif(NOT ${LLVM_BUILD_TYPE} STREQUAL ${CMAKE_BUILD_TYPE})
+  message(WARNING "JitFromScratch set to build as ${CMAKE_BUILD_TYPE}, which differs from LLVM's build type")
+endif()
+
 add_executable(JitFromScratch
   main.cpp
 )
 
 target_include_directories(JitFromScratch PRIVATE
   ${CMAKE_CURRENT_SOURCE_DIR}
+  ${LLVM_INCLUDE_DIRS}
 )
 
+set(llvm_libs
+  LLVMBinaryFormat
+  LLVMCore
+  LLVMDemangle
+  LLVMRemarks
+  LLVMSupport
+)
+
+separate_arguments(LLVM_DEFINITIONS)
+target_compile_definitions(JitFromScratch PRIVATE ${LLVM_DEFINITIONS})
+target_link_libraries(JitFromScratch PRIVATE ${llvm_libs})
+target_compile_options(JitFromScratch PRIVATE ${rtti_flags})
+
 function(dump_target_properties target property)
   get_target_property(values ${target} ${property})
   if(values)

cmake/modules/LLVM.cmake

@@ -0,0 +1,19 @@
+if(LLVM_DIR)
+  file(TO_CMAKE_PATH ${LLVM_DIR} LLVM_DIR)
+  message(STATUS "Configure with explicit LLVM_DIR=${LLVM_DIR}")
+else()
+  message(STATUS
+    "No explicit LLVM_DIR provided. If find_package() fails, pass "
+    "-DLLVM_DIR=/path/to/llvm-build/lib/cmake/llvm to CMake.")
+endif()
+
+find_package(LLVM 9.0 REQUIRED PATHS /usr/local/opt/llvm/lib/cmake/llvm)
+
+if(LLVM_BUILD_MAIN_SRC_DIR)
+  message(STATUS "LLVM Source directory: ${LLVM_BUILD_MAIN_SRC_DIR}")
+  message(STATUS "LLVM Build directory: ${LLVM_BINARY_DIR}")
+else()
+  message(STATUS "LLVM Install directory: ${LLVM_BINARY_DIR}")
+endif()
+
+message(STATUS "LLVM Build type: ${LLVM_BUILD_TYPE}")

main.cpp

@@ -1,5 +1,7 @@
-#include <stdio.h>
-#include <stdlib.h>
+#include <llvm/Support/Format.h>
+#include <llvm/Support/raw_ostream.h>
+
+using namespace llvm;
 
 // Determine the size of a C array at compile-time.
 template <typename T, size_t sizeOfArray>
@@ -39,7 +41,8 @@ int main(int argc, char **argv) {
   int y[]{3, 1, -1};
   int *z = integerDistances(x, y);
 
-  printf("Integer Distances: %d, %d, %d\n\n", z[0], z[1], z[2]);
+  outs() << format("Integer Distances: %d, %d, %d\n\n", z[0], z[1], z[2]);
+  outs().flush();
 
   return 0;
 }