gitea/flake.nix at main · wxiaoguang/gitea · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };
  outputs =
    { nixpkgs, flake-utils, ... }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
      in
      {
        devShells.default =
          with pkgs;
          let
            # only bump toolchain versions here
            go = go_1_25;
            nodejs = nodejs_24;
            python3 = python312;
            pnpm = pnpm_10;

            # Platform-specific dependencies
            linuxOnlyInputs = lib.optionals pkgs.stdenv.isLinux [
              glibc.static
            ];

            linuxOnlyEnv = lib.optionalAttrs pkgs.stdenv.isLinux {
              CFLAGS = "-I${glibc.static.dev}/include";
              LDFLAGS = "-L ${glibc.static}/lib";
            };
          in
          pkgs.mkShell (
            {
              buildInputs = [
                # generic
                git
                git-lfs
                gnumake
                gnused
                gnutar
                gzip
                zip

                # frontend
                nodejs
                pnpm
                cairo
                pixman
                pkg-config

                # linting
                python3
                uv

                # backend
                go
                gofumpt
                sqlite
              ]
              ++ linuxOnlyInputs;

              GO = "${go}/bin/go";
              GOROOT = "${go}/share/go";

              TAGS = "sqlite sqlite_unlock_notify";
              STATIC = "true";
            }
            // linuxOnlyEnv
          );
      }
    );
}