Websocket disconnected when making http request

[jscheel]

I am working on a project where I need to open a websocket, then make an http request. Whenever I make the http request, the websocket is disconnected, and I have no idea why.

#include "./config.h"

#include <Arduino.h>
#include <ESP8266WiFi.h>
#include <ESP8266WiFiMulti.h>
#include <ESP8266HTTPClient.h>
#include <WebSocketsClient.h>
#include <ArduinoJson.h>

ESP8266WiFiMulti WiFiMulti;
WebSocketsClient webSocket;

long nextCmdId = 1;
bool connected = false;
unsigned long lastPing = 0;

void sendPing() {
  DynamicJsonBuffer jsonBuffer;
  JsonObject& root = jsonBuffer.createObject();
  root["type"] = "ping";
  root["id"] = nextCmdId++;
  String json;
  root.printTo(json);
  webSocket.sendTXT(json);
}

void webSocketEvent(WStype_t type, uint8_t *payload, size_t len) {
  switch (type) {
    case WStype_DISCONNECTED:
      Serial.printf("[WebSocket] Disconnected\n");
      connected = false;
      break;

    case WStype_CONNECTED:
      Serial.printf("[WebSocket] Connected to: %s\n", payload);
      sendPing();
      makeTestRequest();
      break;

    case WStype_TEXT:
      Serial.printf("[WebSocket] Message: %s\n", payload);
      break;
  }
}

bool connectToWebSocket() {
  HTTPClient http;
  http.begin(START_ENDPOINT, SSL_FINGERPRINT);
  http.addHeader("Authorization", AUTH_HEADER);
  int httpCode = http.GET();

  if (httpCode != HTTP_CODE_OK) {
    Serial.printf("HTTP GET failed with code %d\n", httpCode);
    http.end();
    return false;
  }

  WiFiClient *client = http.getStreamPtr();
  client->find("wss:\\/\\/");
  String host = client->readStringUntil('\\');
  String path = client->readStringUntil('"');
  path.replace("\\/", "/");

  Serial.println("WebSocket Host=" + host + " Path=" + path);
  webSocket.beginSSL(host, 443, path, "", "");
  webSocket.onEvent(webSocketEvent);
  http.end();
  return true;
}

bool makeTestRequest() {
  HTTPClient http;
  http.begin(TEST_ENDPOINT, SSL_FINGERPRINT);
  http.addHeader("Authorization", AUTH_HEADER);
  int httpCode = http.GET();
  Serial.printf("Test Request HTTP Code: %d\n", httpCode);
  http.end();
  return httpCode == HTTP_CODE_OK;
}

void setup() {
  Serial.begin(115200);
  Serial.setDebugOutput(true);

  WiFiMulti.addAP(WIFI_SSID, WIFI_PASSWORD);
  while (WiFiMulti.run() != WL_CONNECTED) {
    delay(100);
  }

  configTime(3 * 3600, 0, "pool.ntp.org", "time.nist.gov");
}


void loop() {
  webSocket.loop();
  if (connected) {
    if (millis() - lastPing > 5000) {
      sendPing();
      lastPing = millis();
    }
  } else {
    connected = connectToWebSocket();
    if (!connected) {
      delay(500);
    }
  }
}

[jscheel]

So, I'm thinking this is because I don't have an async websocket open. Is this correct?

[Links2004]

the first think that comes in mind ist that the HTTP request takes to long and the other side close the connection since there is no response in time.

can you enable debug for websocket and measure the time the HTTP request needs?
you can use the IDE debug port setting in the menu or
set the define via code change:
https://github.com/Links2004/arduinoWebSockets/blob/master/src/WebSockets.h#L41

in general this will work there is no technical limitation when it comes too use WebSockets and the HTTP client in parallel.

[jscheel]

@Links2004 the disconnect happens immediately when I open the http request

[Links2004]

are both connections HTTPS / SSL ?
the ESP can only handle one SSL connection at a time do to too less RAM.

[jscheel]

Ah, crap, that's it. They both need to be secure.

[Links2004]

if you have a websocket connection you can pipe all data over it and make the second HTTPS request from the server.

[jscheel]

@Links2004 Unfortunately, I am communicating with a 3rd party api. I connect via their realtime websocket server, then need to make http requests intermittently for something their realtime api doesn't support.

[Links2004]

hope you find a workaround for the ESP Limitation.

[b4dnewz]

hi @Links2004
first of all thanks for this great project

I've a similar issue but inverse, I need to do a POST request to an api server and than connect to websockets after it but I don't know why the two things collide here is my code:

In my case the endpoint is not https but localhost:3000 and the client used is ESP8266HTTPClient

// pseudo code for init client
void initClient() bool {
 client.begin(endpoint)
 int res = client.POST(postdata)
 if (res != 200) {
  Serial.print("request has done")
 }
 return res
}

void setup {
  // connect to wifi
  Serial.print("connected to NETWORK_NAME")
 
  initClient();
  // delay(5000);  <-- I tried some delay also
  
  Serial.print("Connect to socket server: ENDPOINT")
  webSocket.beginSocketIO(endpoint, 3000);
  webSocket.setReconnectInterval(10000);
  webSocket.onEvent(webSocketEvent);
}

If I comment out the initClient line it works, if I comment out the webSocket lines it works, I also tried to put a delay between them thinking the POST requests need to wait for the response but still fails.

Here the debug log:

connected to NETWORK_NAME
Sending initialization request to: ENDPOINT
quest to:  <-- this are signs of the potential error part of the string printed before gets printed again
Connect to socket server: ENDPOINT  <-- this line get printed somehow before
request has done  <-- note this line comes from initClient function
[WS-Client] connect ws...
[WS-Client] connected to ENDPOINT
[WS-Client][sendHeader] sending header...

I removed part of the log, simplified and commented some lines, I hope you can understand it.
In substance when initClient() is called even if I put a delay after it the response from the server isn't waited and the next line is called which emit the log "Connect to socket server: ENDPOINT" and tried to connect to the socket endpoint.

It's two days i'm trying to figure out what is the problem, I've no rush but if you can help me is appreciated.

Thanks in advance, Filippo.