git: build /git-bash.exe & /git-cmd.exe, too

mingw-w64-git/PKGBUILD

@@ -4,9 +4,9 @@
 _realname=git
 
 pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
-tag=2.3.3
-pkgver=2.3.3.1.3ee6eff
-pkgrel=1
+tag=2.3.4
+pkgver=2.3.4.2.521863b
+pkgrel=2
 pkgdesc="The fast distributed version control system (mingw-w64)"
 arch=('i686' 'x86_64')
 url="http://git-for-windows.github.io/"
@@ -37,11 +37,35 @@ pkgver() {
   printf "%s.%s.%s" "${tag}" "${pkgrel}" "$(git rev-parse --short HEAD)"
 }
 
+case "$CARCH" in
+i686)
+  SHAREDIR=/mingw32/share/git
+  ;;
+x86_64)
+  SHAREDIR=/mingw64/share/git
+  ;;
+esac
+
 build() {
   export PYTHON_PATH=/usr/bin/python2
   cd "$srcdir/git"
 
-  make -j1 all
+  make -j1 all &&
+
+  gcc -DMAGIC_RESOURCE -mwindows -s -O2 -Wall -o edit-res.exe \
+	compat/win32/git-wrapper.c git.res -lshlwapi &&
+  cp edit-res.exe git-bash.exe &&
+  ./edit-res.exe icon git-bash.exe $startdir/git-for-windows.ico &&
+  ./edit-res.exe command git-bash.exe \
+	"usr\\bin\\mintty.exe -i $SHAREDIR/git-for-windows.ico /usr/bin/bash --login -i" \
+	'@@COMSPEC@@ /C "@@EXEPATH@@\usr\bin\bash.exe" --login -i' &&
+  gcc -DMAGIC_RESOURCE -mconsole -s -O2 -Wall -o git-cmd.exe \
+	compat/win32/git-wrapper.c git.res -lshlwapi &&
+  ./edit-res.exe icon git-cmd.exe $startdir/git-for-windows.ico &&
+  ./edit-res.exe command git-cmd.exe '@@COMSPEC@@ /K' &&
+  mkdir -p cmd &&
+  cp git-wrapper.exe cmd/git.exe &&
+  ./edit-res.exe icon cmd/git.exe $startdir/git-for-windows.ico
 }
 
 package() {
@@ -57,4 +81,14 @@ package() {
 
   # subtree, for backwards-compatibility with MSys2's Git package
   make -C contrib/subtree prefix="$pkgdir/$PREFIX" install
+
+  # Git Bash, Git CMD
+  install -d -m755 $pkgdir$SHAREDIR
+  install -m755 $startdir/git-for-windows.ico $pkgdir$SHAREDIR
+  install -m755 git-bash.exe git-cmd.exe $pkgdir
+
+  # Install Git wrapper into /cmd/
+  install -d -m755 $pkgdir/cmd
+  install -m755 cmd/git.exe $startdir/gitk.cmd $startdir/start-ssh-agent.cmd \
+	$pkgdir/cmd
 }

mingw-w64-git/gitk.cmd

@@ -0,0 +1,13 @@
+@REM Do not use "echo off" to not affect any child calls.
+
+@REM Get the absolute path to the parent directory, which is assumed to be the
+@REM Git installation root.
+@FOR /F "delims=" %%I IN ("%~dp0..") DO @SET toplevel=%%~fI
+@SET MSYSTEM=mingw64
+@IF NOT EXIST "%toplevel%\%MSYSTEM%\bin\git.exe" @SET MSYSTEM=mingw32
+@SET PATH=%toplevel%\%MSYSTEM%\bin;%toplevel%\usr\bin;%PATH%
+
+@IF NOT EXIST "%HOME%" @set HOME=%HOMEDRIVE%%HOMEPATH%
+@IF NOT EXIST "%HOME%" @set HOME=%USERPROFILE%
+
+@START "gitk" wish.exe "%toplevel%\%MSYSTEM%\bin\gitk" -- %*

mingw-w64-git/start-ssh-agent.cmd

@@ -0,0 +1,80 @@
+@REM Do not use "echo off" to not affect any child calls.
+
+@REM Enable extensions, the `verify` call is a trick from the setlocal help
+@VERIFY other 2>nul
+@SETLOCAL EnableDelayedExpansion
+@IF ERRORLEVEL 1 (
+    @ECHO Unable to enable extensions
+    @GOTO failure
+)
+
+@REM Start the ssh-agent if needed by git
+@FOR %%i IN ("git.exe") DO @SET GIT=%%~$PATH:i
+@IF EXIST "%GIT%" (
+    @REM Get the ssh-agent executable
+    @FOR %%i IN ("ssh-agent.exe") DO @SET SSH_AGENT=%%~$PATH:i
+    @IF NOT EXIST "%SSH_AGENT%" (
+        @FOR %%s IN ("%GIT%") DO @SET GIT_DIR=%%~dps
+        @FOR %%s IN ("!GIT_DIR!") DO @SET GIT_DIR=!GIT_DIR:~0,-1!
+        @FOR %%s IN ("!GIT_DIR!") DO @SET GIT_ROOT=%%~dps
+        @FOR %%s IN ("!GIT_ROOT!") DO @SET GIT_ROOT=!GIT_ROOT:~0,-1!
+        @FOR /D %%s in ("!GIT_ROOT!\usr\bin\ssh-agent.exe") DO @SET SSH_AGENT=%%~s
+        @IF NOT EXIST "!SSH_AGENT!" @GOTO ssh-agent-done
+    )
+    @REM Get the ssh-add executable
+    @FOR %%s IN ("!SSH_AGENT!") DO @SET BIN_DIR=%%~dps
+    @FOR %%s in ("!BIN_DIR!") DO @SET BIN_DIR=!BIN_DIR:~0,-1!
+    @FOR /D %%s in ("!BIN_DIR!\ssh-add.exe") DO @SET SSH_ADD=%%~s
+    @IF NOT EXIST "!SSH_ADD!" @GOTO ssh-agent-done
+    @REM Check if the agent is running
+    @FOR /f "tokens=1-2" %%a IN ('tasklist /fi "imagename eq ssh-agent.exe"') DO (
+        @ECHO %%b | @FINDSTR /r /c:"[0-9][0-9]*" > NUL
+        @IF "!ERRORLEVEL!" == "0" @SET SSH_AGENT_PID=%%b
+    )
+    @REM Connect up the current ssh-agent
+    @IF [!SSH_AGENT_PID!] == [] (
+        @ECHO Removing old ssh-agent sockets
+        @FOR /d %%d IN (%TEMP%\ssh-??????*) DO @RMDIR /s /q %%d
+    ) ELSE (
+        @ECHO Found ssh-agent at !SSH_AGENT_PID!
+        @FOR /d %%d IN (%TEMP%\ssh-??????*) DO (
+            @FOR %%f IN (%%d\agent.*) DO (
+                @SET SSH_AUTH_SOCK=%%f
+                @SET SSH_AUTH_SOCK=!SSH_AUTH_SOCK:%TEMP%=/tmp!
+                @SET SSH_AUTH_SOCK=!SSH_AUTH_SOCK:\=/!
+            )
+        )
+        @IF NOT [!SSH_AUTH_SOCK!] == [] (
+            @ECHO Found ssh-agent socket at !SSH_AUTH_SOCK!
+        ) ELSE (
+            @ECHO Failed to find ssh-agent socket
+            SET SSH_AGENT_PID=
+        )
+    )
+    @REM See if we have the key
+    @SET "HOME=%USERPROFILE%"
+    @"!SSH_ADD!" -l 1>NUL 2>NUL
+    @SET result=!ERRORLEVEL!
+    @IF NOT !result! == 0 (
+        @IF !result! == 2 (
+            @ECHO | @SET /p=Starting ssh-agent:
+            @FOR /f "tokens=1-2 delims==;" %%a IN ('"!SSH_AGENT!"') DO (
+                @IF NOT [%%b] == [] @SET %%a=%%b
+            )
+            @ECHO. done
+        )
+        @"!SSH_ADD!"
+        @ECHO.
+    )
+)
+
+:ssh-agent-done
+:failure
+
+@ENDLOCAL & @SET "SSH_AUTH_SOCK=%SSH_AUTH_SOCK%" ^
+          & @SET "SSH_AGENT_PID=%SSH_AGENT_PID%"
+
+@ECHO %cmdcmdline% | @FINDSTR /l "\"\"" >NUL
+@IF NOT ERRORLEVEL 1 (
+    @CALL cmd %*
+)