Pipe Operator

src/grammar.coffee

@@ -582,6 +582,9 @@ grammar =
     # [The existential operator](http://jashkenas.github.com/coffee-script/#existence).
     o 'Expression ?',                           -> new Existence $1
 
+    o 'Expression PIPE Value',                  -> new Call $3, [$1]
+    o 'Expression PIPE Invocation',             -> $3.pipe $1
+
     o 'Expression +  Expression',               -> new Op '+' , $1, $3
     o 'Expression -  Expression',               -> new Op '-' , $1, $3
 
@@ -631,6 +634,7 @@ operators = [
   ['left',      'RELATION']
   ['left',      'COMPARE']
   ['left',      'LOGIC']
+  ['left',      'PIPE']
   ['nonassoc',  'INDENT', 'OUTDENT']
   ['right',     'YIELD']
   ['right',     '=', ':', 'COMPOUND_ASSIGN', 'RETURN', 'THROW', 'EXTENDS']

src/lexer.coffee

@@ -420,6 +420,7 @@ exports.Lexer = class Lexer
       tag = 'TERMINATOR'
     else if value in MATH            then tag = 'MATH'
     else if value in COMPARE         then tag = 'COMPARE'
+    else if value in PIPE            then tag = 'PIPE'
     else if value in COMPOUND_ASSIGN then tag = 'COMPOUND_ASSIGN'
     else if value in UNARY           then tag = 'UNARY'
     else if value in UNARY_MATH      then tag = 'UNARY_MATH'
@@ -806,6 +807,7 @@ NUMBER     = ///
 
 OPERATOR   = /// ^ (
   ?: [-=]>             # function
+   | \|>               # pipe
    | [-+*/%<>&|^!?=]=  # compound assign / compare
    | >>>=?             # zero-fill right shift
    | ([-+:])\1         # doubles
@@ -868,7 +870,7 @@ POSSIBLY_DIVISION   = /// ^ /=?\s ///
 # Other regexes.
 HERECOMMENT_ILLEGAL = /\*\//
 
-LINE_CONTINUER      = /// ^ \s* (?: , | \??\.(?![.\d]) | :: ) ///
+LINE_CONTINUER      = /// ^ \s* (?: , | \??\.(?![.\d]) | :: | \|> ) ///
 
 INVALID_ESCAPE      = ///
   ( (?:^|[^\\]) (?:\\\\)* )        # make sure the escape isn’t escaped
@@ -901,6 +903,8 @@ LOGIC = ['&&', '||', '&', '|', '^']
 # Bit-shifting tokens.
 SHIFT = ['<<', '>>', '>>>']
 
+PIPE = ['|>']
+
 # Comparison tokens.
 COMPARE = ['==', '!=', '<', '>', '<=', '>=']
 

src/nodes.coffee

@@ -609,6 +609,10 @@ exports.Call = class Call extends Base
 
   children: ['variable', 'args']
 
+  pipe: (arg) ->
+    @args.unshift arg
+    this
+
   # Tag this invocation as creating a new instance.
   newInstance: ->
     base = @variable?.base or @variable

test/pipe.coffee

@@ -0,0 +1,39 @@
+
+test "Pipe to function", ->
+
+  fn = (x) -> x * 100
+
+  eq 100, 1 |> fn
+  eq 300, 3 |> fn
+
+test "Pipe to partialy filled function", ->
+
+  fn = (x,y) -> "#{x},#{y}"
+
+  eq '1,2', 1 |> fn(2)
+  eq '1,2', 1 |> fn 2
+
+test "Pipe chain", ->
+
+  f = (x) -> x * 10
+  g = (x) -> x + 5
+
+  eq 15, 1 |> f |> g
+  eq 60, 1 |> g |> f
+
+  add = (x,y) -> x + y
+  mul = (x,y) -> x * y
+
+  eq 45, 4 |> mul(10) |> add 5
+  eq 70, 4 |> add(10) |> mul 5
+
+test "Pipe on the next line", ->
+
+  fn = (x,y) -> "#{x},#{y}"
+
+  eq '1,2', 1
+    |> fn(2)
+
+  eq '1,2', 1
+    |> fn 2
+